VB程序設(shè)計的常用算法

算法（Algorithm）：計算機(jī)解題的基本思想方法和步驟。算法的描述：是對要解決一個問題或要完成一項任務(wù)所采取的方法和步驟的描述，包括需要什么數(shù)據(jù)（輸入什么數(shù)據(jù)、輸出什么結(jié)果）、采用什么結(jié)構(gòu)、使用什么語句以及如何安排這些語句等。通常使用自然語言、結(jié)構(gòu)化流程圖、偽代碼等來描述算法。

一、計數(shù)、求和、求階乘等簡單算法

此類問題都要使用循環(huán)，要注意根據(jù)問題確定循環(huán)變量的初值、終值或結(jié)束條件，更要注意用來表示計數(shù)、和、階乘的變量的初值。

例：用隨機(jī)函數(shù)產(chǎn)生100個[0，99]范圍內(nèi)的隨機(jī)整數(shù)，統(tǒng)計個位上的數(shù)字分別為1，2，3，4，5，6，7，8，9，0的數(shù)的個數(shù)并打印出來。

本題使用數(shù)組來處理，用數(shù)組a(1 to 100)存放產(chǎn)生的確100個隨機(jī)整數(shù)，數(shù)組x(1 to 10)來存放個位上的數(shù)字分別為1，2，3，4，5，6，7，8，9，0的數(shù)的個數(shù)。即個位是1的個數(shù)存放在x(1)中，個位是2的個數(shù)存放在x(2)中，……個位是0的個數(shù)存放在x(10)。

將程序編寫在一個GetTJput過程中，代碼如下：

Public Sub GetTJput()   

    Dim a(1 To 100) As Integer

    Dim x(1 To 10) As Integer

    Dim i As Integer, p As Integer

    '產(chǎn)生100個[0，99]范圍內(nèi)的隨機(jī)整數(shù)，每行10個打印出來

    For i = 1 To 100

        a(i) = Int(Rnd * 100)

        If a(i) < 10 Then

            Form1.Print Space(2); a(i);

        Else

            Form1.Print Space(1); a(i);

        End If

        If i Mod 10 = 0 Then Form1.Print

    Next i

    '統(tǒng)計個位上的數(shù)字分別為1，2，3，4，5，6，7，8，9，0的數(shù)的個數(shù)，并將統(tǒng)計結(jié)果保存在數(shù)組x(1),x(2),...,x(10)中，將統(tǒng)計結(jié)果打印出來

    For i = 1 To 100

        p = a(i)  Mod  10    ' 求個位上的數(shù)字

        If p = 0 Then p = 10

        x(p) = x(p) + 1

    Next i

    Form1.Print "統(tǒng)計結(jié)果"

    For i = 1 To 10

        p = i

        If i = 10 Then p = 0

        Form1.Print "個位數(shù)為" + Str(p) + "共" + Str(x(i)) + "個"

    Next i

End Sub

 

二、求兩個整數(shù)的最大公約數(shù)、最小公倍數(shù)

分析：求最大公約數(shù)的算法思想：(最小公倍數(shù)=兩個整數(shù)之積/最大公約數(shù))

       (1) 對于已知兩數(shù)m，n，使得m>n；

       (2)  m除以n得余數(shù)r；

       (3) 若r=0，則n為求得的最大公約數(shù)，算法結(jié)束；否則執(zhí)行(4)；

       (4) m←n，n←r，再重復(fù)執(zhí)行(2)。

     例如: 求 m=14 ,n=6 的最大公約數(shù).        m      n        r

                                                                         14      6       2

                                             6       2       0

m=inputBox("m=")

n=inputBox("n=")

nm=n*m

If m < n Then t = m: m = n: n = t

    r=m mod n

    Do While (r <> 0)                               

         m=n

         n=r

         r= m mod n

    Loop

    Print "最大公約數(shù)=", n

Print "最小公倍數(shù)=", nm/n

 

三、判斷素數(shù)

只能被1或本身整除的數(shù)稱為素數(shù)  基本思想：把m作為被除數(shù)，將2—INT（ ）作為除數(shù)，如果都除不盡，m就是素數(shù)，否則就不是。（可用以下程序段實現(xiàn)）

m =val( InputBox("請輸入一個數(shù)"))

          For i=2 To int(sqr(m))

               If m Mod i = 0 Then    Exit  For

           Next i

          If i > int(sqr(m)) Then

              Print "該數(shù)是素數(shù)"

          Else

              Print "該數(shù)不是素數(shù)"

          End If

將其寫成一函數(shù),若為素數(shù)返回True，不是則返回False

Private Function Prime( m as Integer)  As  Boolean

                  Dim  i%          

                  Prime=True

                  For i=2 To int(sqr(m))

                      If m Mod i = 0 Then   Prime=False:  Exit  For

                  Next i

             End Function

 

 

 

四、驗證哥德巴赫猜想

（任意一個大于等于6的偶數(shù)都可以分解為兩個素數(shù)之和）

基本思想：n為大于等于6的任一偶數(shù)，可分解為n1和n2兩個數(shù)，分別檢查n1和n2是否為素數(shù)，如都是，則為一組解。如n1不是素數(shù)，就不必再檢查n2是否素數(shù)。先從n1=3開始，檢驗n1和n2（n2=N-n1）是否素數(shù)。然后使n1+2   再檢驗n1、n2是否素數(shù)，… 直到n1=n/2為止。

利用上面的prime函數(shù)，驗證哥德巴赫猜想的程序代碼如下：

Dim  n%,n1%,n2%

       n=Val(InputBox("輸入大于6的正整數(shù)"))

       For n1=3 to n\2 step 2

          n2=n-n1

          If  prime(n1)   Then

               If  prime(n2) then 

                    Print n & "=" & n1 & "+" & n2

                    Exit For                                '結(jié)束循環(huán)

               End if

           End if

       Next  n1

 

 

 

五、排序問題

1．選擇法排序（升序）

基本思想：

1）對有n個數(shù)的序列（存放在數(shù)組a(n)中），從中選出最小的數(shù)，與第1個數(shù)交換位置；

2）除第1 個數(shù)外，其余n-1個數(shù)中選最小的數(shù)，與第2個數(shù)交換位置；

3）依次類推，選擇了n-1次后，這個數(shù)列已按升序排列。

 

程序代碼如下：

For i = 1 To n - 1

        imin = i

        For j = i + 1 To n

            If a(imin) > a(j) Then imin = j

        Next j

        temp = a(i)

        a(i) = a(imin)

        a(imin) = temp

Next I

 

2．冒泡法排序（升序）

  基本思想：(將相鄰兩個數(shù)比較，小的調(diào)到前頭)

1）有n個數(shù)（存放在數(shù)組a(n)中），第一趟將每相鄰兩個數(shù)比較，小的調(diào)到前頭，經(jīng)n-1次兩兩相鄰比較后，最大的數(shù)已“沉底”，放在最后一個位置，小數(shù)上升“浮起”；

2）第二趟對余下的n-1個數(shù)（最大的數(shù)已“沉底”）按上法比較，經(jīng)n-2次兩兩相鄰比較后得次大的數(shù)；

3）依次類推，n個數(shù)共進(jìn)行n-1趟比較，在第j趟中要進(jìn)行n-j次兩兩比較。

程序段如下

For i = 1 To n - 1

   For j = 1 To n-i

        If a(j) > a(j+1) Then

           temp=a(j)： a(j)=a(j+1)： a(j+1)=temp

        End if

   Next j

Next i

 

 

3．合并法排序（將兩個有序數(shù)組A、B合并成另一個有序的數(shù)組C，升序）

基本思想：

1）先在A、B數(shù)組中各取第一個元素進(jìn)行比較，將小的元素放入C數(shù)組；

2）取小的元素所在數(shù)組的下一個元素與另一數(shù)組中上次比較后較大的元素比較，重復(fù)上述比較過程，直到某個數(shù)組被先排完；

3）將另一個數(shù)組剩余元素抄入C數(shù)組，合并排序完成。

程序段如下：

   Do While ia <= UBound(A) And ib <= UBound(B)   '當(dāng)A和B數(shù)組均未比較完

          If A(ia) < B(ib) Then

                C(ic) = A(ia)：  ia = ia + 1

          Else

                C(ic) = B(ib)：  ib = ib + 1

          End If

          ic = ic + 1

    Loop

    Do While ia <= UBound(A)    'A數(shù)組中的剩余元素抄入C數(shù)組

          C(ic) = A(ia)

          ia = ia + 1：   ic = ic + 1

    Loop

    Do While ib <= UBound(B)   'B數(shù)組中的剩余元素抄入C數(shù)組

           C(ic) = B(ib)

            ib = ib + 1：  ic = ic + 1

    Loop

 

 

六、查找問題

1．①順序查找法（在一列數(shù)中查找某數(shù)x）

  基本思想：一列數(shù)放在數(shù)組a(1)---a(n)中，待查找的數(shù)放在x 中，把x與a數(shù)組中的元素從頭到尾一一進(jìn)行比較查找。用變量p表示a數(shù)組元素下標(biāo)，p初值為1，使x與a(p)比較，如果x不等于a(p)，則使p=p+1，不斷重復(fù)這個過程；一旦x等于a(p)則退出循環(huán)；另外，如果p大于數(shù)組長度，循環(huán)也應(yīng)該停止。（這個過程可由下語句實現(xiàn)）

    p = 1

    Do While x <> a(p) And p < =n

        p = p + 1

    Loop

下面寫一查找函數(shù)Find，若找到則返回下標(biāo)值，找不到返回0

Option Base 1

Private Function Find( a( ) As Single,x As Single)  As Integer

      Dim n%,p%

      n=Ubound( a )

p = 1

Do While x <> a(p) And p < =n

         p = p + 1

Loop

      If  p>n then  p=0

       Find=p

End Function   

 

②基本思想：一列數(shù)放在數(shù)組a(1)---a(n)中，待查找的關(guān)鍵值為key，把key與a數(shù)組中的元素從頭到尾一一進(jìn)行比較查找，若相同，查找成功，若找不到，則查找失敗。(查找子過程如下。index：存放找到元素的下標(biāo)。)

Public Sub Search(a() As Variant, key As Variant, index%)

  Dim i%

  For i = LBound(a) To UBound(a)

    If key = a(i) Then

      index = i

      Exit Sub

    End If

  Next i

    index = -1

End Sub

 

2．折半查找法（只能對有序數(shù)列進(jìn)行查找）

基本思想：設(shè)n個有序數(shù)（從小到大）存放在數(shù)組a(1)----a(n)中，要查找的數(shù)為x。用變量bot、top、mid 分別表示查找數(shù)據(jù)范圍的底部（數(shù)組下界）、頂部（數(shù)組的上界）和中間，mid=(top+bot)/2，折半查找的算法如下：

（1）x=a(mid)，則已找到退出循環(huán)，否則進(jìn)行下面的判斷；

（2）x<a(mid)，x必定落在bot和mid-1的范圍之內(nèi)，即top=mid-1；

（3）x>a(mid)，x必定落在mid+1和top的范圍之內(nèi)，即bot=mid+1；

（4）在確定了新的查找范圍后，重復(fù)進(jìn)行以上比較，直到找到或者bot<=top。

將上面的算法寫成如下函數(shù)，若找到則返回該數(shù)所在的下標(biāo)值，沒找到則返回-1。

Function search(a() As Integer, x As Integer) As Integer

    Dim bot%, top%, mid%

    Dim find As Boolean   '代表是否找到

    bot = LBound(a)

    top = UBound(a)

    find = False          '判斷是否找到的邏輯變量，初值為False

    Do While bot <= top And Not find

         mid = (top + bot) \ 2

        If x = a(mid) Then

            find = True

            Exit Do

          ElseIf x < a(mid) Then

              top = mid - 1

            Else

              bot = mid + 1

            End If

        Loop

    If find Then

       search = mid

     Else

       search = -1

    End If

End Function

 

 

七、插入法

把一個數(shù)插到有序數(shù)列中，插入后數(shù)列仍然有序

基本思想：n個有序數(shù)（從小到大）存放在數(shù)組a(1)—a(n)中，要插入的數(shù)x。首先確定x插在數(shù)組中的位置P；（可由以下語句實現(xiàn)）

p=1

do while x>a(p) and p<=n

p=p+1

loop

a(p)—a(n)元素向后順移一個位置以空出a(p)元素放入x，可由以下語句實現(xiàn)：

for i=n to p  step-1

  a(i+1)=a(i)

next i

a(p)=x

將其寫成一插入函數(shù)

Private Sub Instert(a() As Single, x As Single)

            Dim p%, n%, i%

            n = UBound(a)

            ReDim Preserve a(n + 1)

            p = 0

            Do While x > a(p) And p < =n    ' 確定x應(yīng)插入的位置

                  p = p + 1

            Loop

            For i = n To p Step -1

              a(i + 1) = a(i)

            Next i

            a(p) = x

     End Sub

 

 

八、矩陣（二維數(shù)組）運算

（1）矩陣的加、減運算

           C(i,j)=a(i,j)+b(i,j)           加法

           C(i,j)=a(i,j)-b(i,j)            減法

 

（2）矩陣相乘

（矩陣A有M*L個元素，矩陣B有L*N個元素，則矩陣C=A*B有M*N個元素）。矩陣C中任一元素   (i=1,2,…,m;   j=1,2,…,n)

For i = 0 To m                             

For j = 0 To n                              

      c(i, j) = 0                             

       For k = 0 To l                           

        c(i, j) = c(i, j) + a(i, k) * b(k, j)            

      Next k                                 

  Next j                               

 Next i                                  

 

（3）矩陣傳置

例:有二維數(shù)組a(5,5)，要對它實現(xiàn)轉(zhuǎn)置，可用下面兩種方式：

For i=1 to 5                                                             (2)     For i=2 to 5

For j=i+1 to 5                                                                    For j=1 to i

t=a(i,j)                                                                        t=a(i,j)

a(i,j)= a(j,i)                         a(i,j)= a(j,i)

a(j,i)=t                             a(j,i)=t

Next j                                                                                Next j

Next i                                                                                       Next i

 

（4）求二維數(shù)組中最小元素及其所在的行和列                                                                                                          

基本思路同一維數(shù)組，可用下面程序段實現(xiàn)（以二維數(shù)組a(2,3)為例）：

‘變量max中存放最大值，row,column存放最大值所在行列號

Max = a(1, 1): row = 1: Column = 1

For i = 1 To 2

    For j = 1 To 3

        If a(i, j) > a(row, Column) Then

            Max = a(i, j)

            row = i

            Column = j

        End If

    Next j

Next i

Print "最大元素是"; Max

Print "在第" & row & "行,"; "第" & Column & "列"

九、迭代法

算法思想：

對于一個問題的求解x，可由給定的一個初值x0，根據(jù)某一迭代公式得到一個新的值x1，這個新值x1比初值x0更接近要求的值x；再以新值作為初值，即：x1→x0,重新按原來的方法求x1,重復(fù)這一過和直到|x1-x0|<ε(某一給定的精度)。此時可將x1作為問題的解。

例：用迭代法求某個數(shù)的平方根。 已知求平方根的迭代公式為：

Private Function Fsqrt( a As single ) AS single

Dim x0 As Single, x1 As Single

     x0 =a/2          '迭代初值

     x1 = 0.5*(x0 + a/x0)

     Do

            x0 = x1   '為下一次迭代作準(zhǔn)備

            x1 = 0.5*(x0 + a/x0)

    Loop While Abs(x1 - x0) > 0.00001

    Fsqrt=x1

End Function

十、數(shù)制轉(zhuǎn)換

     將一個十進(jìn)制整數(shù)m轉(zhuǎn)換成 →r(2－16)進(jìn)制字符串。

方法：將m不斷除 r 取余數(shù)，直到商為零，以反序得到結(jié)果。下面寫出一轉(zhuǎn)換函數(shù)，參數(shù)idec為十進(jìn)制數(shù)，ibase為要轉(zhuǎn)換成數(shù)的基（如二進(jìn)制的基是2，八進(jìn)制的基是8等），函數(shù)輸出結(jié)果是字符串。

Private Function TrDec(idec As Integer, ibase As Integer) As String

     Dim strDecR$, iDecR%

     strDecR = ""

     Do While idec <> 0

          iDecR = idec Mod ibase

          If iDecR >= 10 Then

             strDecR = Chr$(65 + iDecR - 10) & strDecR

          Else

             strDecR = iDecR & strDecR

          End If

          idec = idec \ ibase

    Loop

   TrDec = strDecR

 End Function

十一、字符串的一般處理

1．簡單加密和解密

 

加密的思想是：

  將每個字母C加（或減）一序數(shù)K，即用它后的第K個字母代替，變換式公式： c=chr(Asc(c)+k)

    例如序數(shù)k為5，這時 "A"→ "F"， "a"→?"f"，"B"→?"G"…

    當(dāng)加序數(shù)后的字母超過"Z"或"z"則 c=Chr(Asc(c)+k -26)

         例如：You  are  good→ Dtz   fwj  ltti

 

   解密為加密的逆過程

    將每個字母C減（或加）一序數(shù)K，即 c=chr(Asc(c)-k),

    例如序數(shù)k為5，這時 "Z"→"U"， "z"→"u"，"Y"→"T"…

  當(dāng)加序數(shù)后的字母小于"A"或"a"則 c=Chr(Asc(c)-k +26)

下段程序是加密處理：

i = 1:   strp = ""

nL = Len(RTrim(strI))

Do While (i <= nL)

       strT = Mid$(strI, i, 1)     '取第i個字符

       If (strT >= "A" And strT <= "Z") Then

             iA = Asc(strT) + 5

             If iA > Asc("Z") Then iA = iA - 26

             strp = strp + Chr$(iA)

       ElseIf (strT >= "a" And strT <= "z") Then

              iA = Asc(strT) + 5

              If iA > Asc("z") Then iA = iA - 26

              strp = strp + Chr$(iA)

            Else

        strp = strp + strT

        End If

        i = i + 1

    Loop

Print strp

 

2．統(tǒng)計文本單詞的個數(shù)

 

算法思路：

 （1）從文本（字符串）的左邊開始，取出一個字符；設(shè)邏輯量WT表示所取字符是否是單詞內(nèi)的字符，初值設(shè)為False

 （2）若所取字符不是“空格”，“逗號”，“分號”或“感嘆號”等單詞的分隔符，再判斷WT是否為True，若WT不為True則表是新單詞的開始，讓單詞數(shù)Nw=Nw+1，讓WT=True;

 （3）若所取字符是“空格”，“逗號”，“分號”或“感嘆號”等單詞的分隔符， 則表示字符不是單詞內(nèi)字符，讓WT=False;

(4)        再依次取下一個字符，重得（2）(3)直到文本結(jié)束。

下面程序段是字符串strI中包含的單詞數(shù)

Nw = 0: Wt = False

nL = Len(RTrim(strI))

For i = 1 To nL

      strT = Mid$(strI, i, 1)     '取第i個字符

      Select Case strT

            Case " ", ",", ";", "!"

                  Wt = False

            Case Else

                  If Not Wt Then

                       Nw = Nw + 1

                       Wt = True

                  End If

       End Select

Next i

Print "單詞數(shù)為：", Nw

 

十二、窮舉法

窮舉法（又稱“枚舉法”）的基本思想是：一一列舉各種可能的情況，并判斷哪一種可能是符合要求的解，這是一種“在沒有其它辦法的情況的方法”，是一種最“笨”的方法，然而對一些無法用解析法求解的問題往往能奏效，通常采用循環(huán)來處理窮舉問題。

例： 將一張面值為100元的人民幣等值換成100張5元、1元和0.5元的零鈔，要求每種零鈔不少于1張，問有哪幾種組合？

Dim i%, j%, k%

Print "5元             1元          0.5元"

For i = 1 To 20

        For j = 1 To 100 - i

               k = 100 - i - j

               If 5.0 * i + 1.0 * j + 0.5 * k = 100 Then

                   Print i, j, k

               End If

         Next j

   Next i

 

 

 

十三、遞歸算法

用自身的結(jié)構(gòu)來描述自身，稱遞歸

VB允許在一個Sub子過程和Function過程的定義內(nèi)部調(diào)用自己，即遞歸Sub子過程和遞歸Function函數(shù)。遞歸處理一般用棧來實現(xiàn)，每調(diào)用一次自身，把當(dāng)前參數(shù)壓棧，直到遞歸結(jié)束條件；然后從棧中彈出當(dāng)前參數(shù)，直到?？?。

遞歸條件：（1）遞歸結(jié)束條件及結(jié)束時的值；（2）能用遞歸形式表示，且遞歸向終止條件發(fā)展。

例：編fac(n)=n! 的遞歸函數(shù)

      Function fac(n As Integer) As Integer

          If n = 1 Then

                 fac = 1

          Else

      fac = n * fac(n - 1)

          End If

End Function