五彩K線指標(biāo)公式集

老土360 2010-07-08

展開全文

五彩K線指標(biāo)公式集

五彩K線公式：K110 (早晨之星) 缺省周期：日線
BACKSET(
REF(CLOSE,2)/REF(OPEN,2) < 0.95 AND
REF(OPEN,1) < REF(CLOSE,2) AND
ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.03 AND
CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2),
3)

五彩K線公式：K120 (黃昏之星) 缺省周期：日線
BACKSET(
REF(CLOSE,2)/REF(OPEN,2) > 1.03 AND
REF(OPEN,1) > REF(CLOSE,2) AND
ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.02 AND
CLOSE/OPEN<0.97 AND CLOSE<REF(CLOSE,2),
3)

五彩K線公式：K130 (十字星) 缺省周期：日線
CLOSE=OPEN AND HIGH<>LOW

五彩K線公式：K132 (長十字) 缺省周期：日線
CLOSE=OPEN AND
HIGH/LOW > 1.03

五彩K線公式：K134 (垂死十字) 缺省周期：日線
CLOSE=OPEN AND
CLOSE=LOW AND
CLOSE<>HIGH

五彩K線公式：K140 (早晨十字星) 缺省周期：日線
BACKSET(
REF(CLOSE,2)/REF(OPEN,2) < 0.95 AND
REF(OPEN,1) < REF(CLOSE,2) AND
REF(OPEN,1)=REF(CLOSE,1) AND
CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2),
3)

五彩K線公式：K150 (黃昏十字星) 缺省周期：日線
BACKSET(
REF(CLOSE,2)/REF(OPEN,2) > 1.05 AND
REF(OPEN,1) > REF(CLOSE,2) AND
REF(OPEN,1)=REF(CLOSE,1) AND
CLOSE/OPEN<0.95 AND CLOSE<REF(CLOSE,2),
3)

五彩K線公式：K160 (射擊之星) 缺省周期：日線
MIN(OPEN,CLOSE)=LOW AND
HIGH-LOW > 3*(MAX(OPEN,CLOSE)-LOW) AND
CLOSE > MA(CLOSE,5)

五彩K線公式：K165 (倒轉(zhuǎn)錘頭) 缺省周期：日線
MIN(OPEN,CLOSE)=LOW AND
HIGH-LOW > 3*(MAX(OPEN,CLOSE)-LOW) AND
CLOSE < MA(CLOSE,5)

五彩K線公式：K170 (錘頭) 缺省周期：日線
HIGH = MAX(OPEN,CLOSE) AND
HIGH-LOW > 3*(HIGH-MIN(OPEN,CLOSE)) AND
CLOSE < MA(CLOSE,5)

五彩K線公式：K180 (吊頸) 缺省周期：日線
HIGH = MAX(OPEN,CLOSE) AND
HIGH-LOW > 3*(HIGH-MIN(OPEN,CLOSE)) AND
CLOSE > MA(CLOSE,5)

五彩K線公式：K190 (穿頭破腳) 缺省周期：日線
BACKSET(
(REF(CLOSE,1)/REF(OPEN,1)>1.03 AND
CLOSE/OPEN<0.96 AND
CLOSE<REF(OPEN,1) AND OPEN>REF(CLOSE,1))
OR
(REF(CLOSE,1)/REF(OPEN,1)<0.97 AND
CLOSE/OPEN>1.04 AND
CLOSE>REF(OPEN,1) AND OPEN<REF(CLOSE,1)),
2)

五彩K線公式：K200 (烏云蓋頂) 缺省周期：日線
BACKSET(
REF(CLOSE,1)/REF(OPEN,1)>1.03 AND
CLOSE/OPEN<0.97 AND
OPEN>REF(CLOSE,1) AND
CLOSE<REF(CLOSE,1),
3)

五彩K線公式：K210 (曙光初現(xiàn)) 缺省周期：日線
BACKSET(
REF(CLOSE,1)/REF(OPEN,1)<0.97 AND
CLOSE/OPEN>1.03 AND
OPEN<REF(CLOSE,1) AND
CLOSE>REF(CLOSE,1),
2)

五彩K線公式：K220 (身懷六甲) 缺省周期：日線
BACKSET(
ABS(REF(CLOSE,1)-REF(OPEN,1))/REF(CLOSE,1) > 0.04 AND
ABS(CLOSE-OPEN)/CLOSE<0.005 AND
MAX(CLOSE,OPEN) < MAX(REF(CLOSE,1),REF(OPEN,1)) AND
MIN(CLOSE,OPEN) > MIN(REF(CLOSE,1),REF(OPEN,1)),
2)

五彩K線公式：K230 (十字胎) 缺省周期：日線
BACKSET(
ABS(REF(CLOSE,1)-REF(OPEN,1))/REF(CLOSE,1) > 0.04 AND
CLOSE=OPEN AND
CLOSE < MAX(REF(CLOSE,1),REF(OPEN,1)) AND
CLOSE > MIN(REF(CLOSE,1),REF(OPEN,1)),
2)

五彩K線公式：K240 (平頂) 缺省周期：日線
BACKSET(ABS(HIGH-REF(HIGH,1))/HIGH<0.001,2)

五彩K線公式：K250 (平底) 缺省周期：日線
BACKSET((ABS(LOW-REF(LOW,1))/LOW<0.001 and
abs(ref(low,1)-ref(low,2))/ref(low,1)<=0.001),2)

五彩K線公式：K260 (大陽燭) 缺省周期：日線
CLOSE/OPEN>1.05 AND
HIGH/LOW < CLOSE/OPEN+0.018

五彩K線公式：K270 (大陰燭) 缺省周期：日線
OPEN/CLOSE > 1.05 AND
HIGH/LOW < OPEN/CLOSE+0.018

五彩K線公式：K280 (好友反攻) 缺省周期：日線
BACKSET(
(REF(CLOSE,1)<REF(OPEN,1) AND
CLOSE>OPEN AND
ABS(CLOSE-REF(CLOSE,1))/CLOSE<0.002)
OR
(REF(CLOSE,1)>REF(OPEN,1) AND
CLOSE<OPEN AND
ABS(CLOSE-REF(CLOSE,1))/CLOSE<0.002),
2)

五彩K線公式：K290 (跳空缺口) 缺省周期：日線
BACKSET(
HIGH<REF(LOW,1) OR
LOW>REF(HIGH,1),
2)

五彩K線公式：K300 (三個白武士) 缺省周期：日線
BACKSET(
REF(CLOSE,2)>REF(OPEN,2) AND
REF(CLOSE,1)>REF(OPEN,1) AND
CLOSE>OPEN AND
REF(CLOSE,1)>REF(CLOSE,2) AND
CLOSE>REF(CLOSE,1),
3)

五彩K線公式：K310 (三只烏鴉) 缺省周期：日線
BACKSET(
REF(CLOSE,2)<REF(OPEN,2) AND
REF(CLOSE,1)<REF(OPEN,1) AND
CLOSE<OPEN AND
REF(CLOSE,1)<REF(CLOSE,2) AND
CLOSE<REF(CLOSE,1),
3)

五彩K線公式：K320 (雙飛烏鴉) 缺省周期：日線
BACKSET(
REF(CLOSE,1)<REF(OPEN,1) AND
CLOSE<OPEN AND
CLOSE/OPEN<0.98,
1)

五彩K線公式：K330 (上升三部曲) 缺省周期：日線
BACKSET(
REF(CLOSE,4)/REF(OPEN,4)>1.03 AND
REF(CLOSE,3)<REF(OPEN,3) AND
REF(CLOSE,2)<REF(OPEN,2) AND
REF(CLOSE,1)<REF(OPEN,1) AND
REF(LOW,4)<REF(LOW,3) AND
REF(LOW,4)<REF(LOW,2) AND
REF(LOW,4)<REF(LOW,1) AND
REF(HIGH,4)>REF(HIGH,3) AND
REF(HIGH,4)>REF(HIGH,2) AND
REF(HIGH,4)>REF(HIGH,1) AND
CLOSE/OPEN>1.03 AND
CLOSE>REF(CLOSE,4),
5)

五彩K線公式：K340 (下跌三部曲) 缺省周期：日線
BACKSET(
REF(CLOSE,4)/REF(OPEN,4)<0.97 AND
REF(CLOSE,3)>REF(OPEN,3) AND
REF(CLOSE,2)>REF(OPEN,2) AND
REF(CLOSE,1)>REF(OPEN,1) AND
REF(LOW,4)<REF(LOW,3) AND
REF(LOW,4)<REF(LOW,2) AND
REF(LOW,4)<REF(LOW,1) AND
REF(HIGH,4)>REF(HIGH,3) AND
REF(HIGH,4)>REF(HIGH,2) AND
REF(HIGH,4)>REF(HIGH,1) AND
CLOSE/OPEN<0.97 AND
CLOSE<REF(CLOSE,4),
5)

五彩K線公式：K350 (長下影) 缺省周期：日線
(MIN(CLOSE,OPEN)-LOW)/(HIGH-LOW)>0.667

五彩K線公式：K360 (長上影) 缺省周期：日線
(HIGH-MAX(CLOSE,OPEN))/(HIGH-LOW)>0.667,COLORBLUE

五彩K線公式：K370 (分離) 缺省周期：日線
BACKSET(
OPEN=REF(OPEN,1) AND
(CLOSE-OPEN)*(REF(CLOSE,1)-REF(OPEN,1))<0,
2)

五彩K線公式：K380 (光頭陽線) 缺省周期：日線
HIGH=CLOSE AND
HIGH<>LOW

五彩K線公式：K390 (光腳陰線) 缺省周期：日線
LOW=CLOSE AND
HIGH<>LOW

五彩K線公式：K400 (孕育線) 缺省周期：日線
參數(shù)描述： N(1,100,2)N1(1,100,2)N2(1,100,2)N3(1,100,1)
BACKSET(REF(CLOSE,2)>REF(OPEN,2) AND
(REF(CLOSE,2)-REF(OPEN,2))/REF(OPEN,2)>=N/100 AND
REF(OPEN,1)>=REF(CLOSE,1) AND
(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<=N1/100 AND
REF(OPEN,1)<=REF(CLOSE,2) AND REF(CLOSE,1)>=REF(OPEN,2) AND
C>=OPEN AND
(CLOSE-OPEN)/OPEN>=N2/100
AND CLOSE>=REF(OPEN,1) AND OPEN<=REF(CLOSE,1)
AND (MAX(CLOSE,REF(C,2))-MIN(CLOSE,REF(CLOSE,2)))/MIN(CLOSE,REF(CLOSE,2))<=N3/100
,3)

同花順五彩K線

早晨之星

a1=ABS(CLOSE-OPEN)/OPEN<0.005 AND (HIGH-LOW)/ABS(CLOSE-OPEN)>2;
a2=COUNT(a1,2)==1 AND COUNT(a1,1)==0;
a3=REF(LOW,1)==LLV(LOW,13) AND REF(CLOSE,1)==LLV(CLOSE,13);
a=a2*a3;
IF(a==1)RETURN BACKSET("colorred",2);
ELSE RETURN("colorgreen");

黃昏之星

a1=ABS(CLOSE-OPEN)/OPEN<0.01 AND (HIGH-LOW)/ABS(CLOSE-OPEN)>2;
a2=COUNT(a1,2)==1 AND COUNT(a1,1)==0;
a3=REF(HIGH,1)==HHV(HIGH,13) AND REF(CLOSE,1)==HHV(CLOSE,13);
a=a2*a3;
IF(a==1)RETURN BACKSET("colorred",2);
ELSE RETURN("colorgreen");

十字星

IF(CLOSE==OPEN AND HIGH!=CLOSE AND LOW!=CLOSE) RETURN("colorred");
ELSE RETURN("colorgreen");

長十字星

IF(CLOSE==OPEN AND HIGH!=CLOSE AND LOW!=CLOSE AND HIGH/LOW>1.03) RETURN("colorred");
ELSE RETURN("colorgreen");

垂死丁字

IF(CLOSE==OPEN AND CLOSE==LOW AND CLOSE!=HIGH) RETURN("colorred");
ELSE RETURN("colorgreen");

射擊之星

IF(MIN(OPEN,CLOSE)==LOW AND (HIGH-LOW)> 3*(MAX(OPEN,CLOSE)-LOW)
AND CLOSE > MA(CLOSE,5)) RETURN("colorred");
ELSE RETURN("colorgreen");

穿頭破腳

IF(CLOSE[1]/OPEN[1]>1.03 AND CLOSE/OPEN<0.96 AND
CLOSE<OPEN[1] AND OPEN>CLOSE[1])
{
BACKSET("colorred",1);
RETURN("colorgreen");
}
IF(CLOSE[1]/OPEN[1]<0.97 AND
CLOSE/OPEN>1.04 AND CLOSE>OPEN[1] AND OPEN<CLOSE[1])
{
BACKSET("colorgreen",1);
RETURN("colorred");
}
ELSE RETURN("coloryellow");

三紅兵

IF(CLOSE[2]>OPEN[2] AND CLOSE[1]>OPEN[1] AND CLOSE>OPEN AND
CLOSE[1]>CLOSE[2] AND CLOSE>CLOSE[1])
{RETURN BACKSET("colorred",2);}
ELSE RETURN "colorgreen";

三只烏鴉

IF(CLOSE[2]<OPEN[2] AND CLOSE[1]<OPEN[1] AND CLOSE<OPEN AND
CLOSE[1]<CLOSE[2] AND CLOSE<CLOSE[1])
{
RETURN BACKSET("colorgreen",2);
}
ELSE RETURN("colorred");

光頭陽線

IF(HIGH==CLOSE AND HIGH!=LOW)
{RETURN "colorred";}
ELSE RETURN "colorgreen"

紅綠燈

RSV=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K=SMA(RSV,M1,1);
D=SMA(K,M2,1);
W=-100*(HHV(HIGH,100)-CLOSE)/(HHV(HIGH,100)-LLV(LOW,100));
W1=-100*(HHV(HIGH,52)-CLOSE)/(HHV(HIGH,52)-LLV(LOW,52));
IF(CLOSE>OPEN AND D>15 AND K>12 AND D<82 AND K<88) RETURN "COLORRED";
ELSE IF(D<15 AND K<12) RETURN "COLORYELLOW";
ELSE IF(D>82 AND K>88) RETURN "COLORGREEN";
ELSE IF(W>-0.01) RETURN "COLORBLUE";
ELSE IF(W1<-99.9) RETURN "COLORWHITE";
ELSE RETURN "COLORGREEN"

操盤區(qū)域

a1=CLOSE>MA(CLOSE,n);
a2=CLOSE>MA(CLOSE,m) AND CLOSE<MA(CLOSE,n);
IF(a1==1)RETURN ("colorred");
ELSE IF (a2==1) RETURN("coloryellow");
ELSE RETURN("colorgreen");

平臺整理

(HHV(HIGH,N)-LLV(LOW,N))/LLV(LOW,N)<=(m/100)