0001 主圖顯示代碼及板塊 0026 上影線 0051 基本配色：灰色峰 0076 橫向統(tǒng)計(jì)
0002 主圖顯示成交量 0027 本周期的漲跌幅 0052 基本配色：綠藍(lán)峰 0077 擴(kuò)展數(shù)據(jù)
0003 預(yù)測全天成交量、換手率 0028 振幅 0053 K線最高最低向右平行線 0078 峰點(diǎn)公式
0004 收盤線（主圖） 0029 均線金叉 0054 顯示無數(shù)條線 0079 窄幅整理
0005 時(shí)間周期線（主圖疊加） 0030 均線死叉 0055 底背離 0080 N天前到M天前之間最高價(jià)
0006 BACKSET()函數(shù)高級用法 0031 均線多頭排列 0056 頂背離 0081 某時(shí)間段最高價(jià)
0007 MACD金死叉間最大最小值 0032 均線空頭排列 0057 N次金叉、死叉 0082 二十日內(nèi)是否有過漲停
0008 曲線在N天內(nèi)平均變化率 0033 N日均線向下 0058 5分副圖顯示15分K線 0083 放量創(chuàng)新高
0009 變動(dòng)角 0034 N日均線向上 0059 移動(dòng)成本 0084 突破長期平臺(tái)整理
0010 曲線上兩點(diǎn)的連線的斜率 0035 N日均線走平 0060 妙用SUMBARS()函數(shù) 0085 尾盤大單拉升或打壓
0011 傾角 0036 前N日至M日出過死叉 0061 取得K線的序號 0086 MACD柱狀體變寬語法
0012 交叉點(diǎn) 0037 今成交量大于N日均量 0062 變量宣告 0087 傅立葉變換
0013 下拐點(diǎn)(由下向上轉(zhuǎn)) 0038 低位密集 0063 跨周期引用數(shù)據(jù) 0088 周期切換
0014 上拐點(diǎn)(由上向下轉(zhuǎn)) 0039 換手率 0064 未來數(shù)據(jù)、未知數(shù)據(jù) 0089 公歷農(nóng)歷
0015 位置(交叉點(diǎn)到當(dāng)前周期) 0040 N日盈虧 0065 主圖KD 0090 添加特色指針子選單
0016 曲線A疊加曲線B 0041 曲線疊加 0066 描繪K線 0091 5日均線轉(zhuǎn)折價(jià)
0017 兩條指標(biāo)線兩次金叉通式 0042 均線變色 0067 分時(shí)K線當(dāng)天K線序號 0092 平均真實(shí)波幅ATRBANDS
0018 今收對N日內(nèi)低收盤漲幅 0043 基本配色：白紅峰 0068 系統(tǒng)參數(shù)函數(shù) 0093 SYSPARAM(1)函數(shù)的說明
0019 今收對N日內(nèi)高收盤跌幅 0044 基本配色：白晶峰 0069 概率統(tǒng)計(jì) 0094 真實(shí)波幅平均真實(shí)波幅
0020 股價(jià)N日內(nèi)運(yùn)行相對位置 0045 基本配色：白藍(lán)峰 0070 五彩K線常用顏色 0095 向后到水平線跌破
0021 股價(jià)上方籌碼（%） 0046 基本配色：白綠峰 0071 公式設(shè)定注意事項(xiàng) 0096 分析周期切換(1)
0022 股價(jià)下方籌碼（%） 0047 基本配色：淡紫峰 0072 交易系統(tǒng)公式交易類型 0097 分析周期切換(2)
0023 收盤價(jià)N%處的套牢盤 0048 基本配色：黃褐峰 0073 可供引用的周期類型 0098 調(diào)用某公式內(nèi)時(shí)間數(shù)列線
0024 收盤價(jià)N%處的獲利盤 0049 基本配色：黃紅峰 0074 引用表達(dá)式 0099 三角函數(shù)AND角度線
0025 下影線 0050 基本配色：黃綠峰 0075 符號一覽表 0100 個(gè)股和大盤聯(lián)動(dòng)K線
公式技巧(0001)
【 發(fā)布:于瑤 2004-10-03 22:08 股市脈望 瀏覽/回復(fù)：970/99】
0001--主圖顯示代碼及板塊
一、顯示板塊
例一：
DRAWTEXT(BARPOS=SYSPARAM(2),H,'\N所屬板塊:'+BLKNAME),ALIGN4,COLORYELLOW;
例二：
DRAWTEXT(SYSPARAM(2)=BARPOS,C,'所屬板塊:'+BLKNAME),ALIGN4,COLORYELLOW;
例三：
DRAWTEXT(SYSPARAM(2)=BARSCOUNT(C),H,'[所屬版塊]:'+BLKNAME),ALIGN4,COLORYELLOW;
二、顯示代碼及板塊
S:=STKLABEL;
DRAWTEXT(SYSPARAM(2)=BARPOS,C,S),ALIGN4,COLORYELLOW;
DRAWTEXT(BARPOS=SYSPARAM(2),H,'\N 所屬板塊:'+BLKNAME),ALIGN4,COLORYELLOW;{N與所屬板塊之間空六格，以顯示代碼}
工具箱
【 · 發(fā)布:于瑤 2004-10-05 22:34 】
0031--均線多頭排列
A1:=MA(C,N1);
A2:=MA(C,N2);
A3:=MA(C,N3);
A4:=MA(C,N4);
COUNT(A1>A2 AND A2>A3 AND A3>A4,3);
工具箱
【 · 發(fā)布:于瑤 2004-10-05 22:34 】
0032--均線空頭排列
A1:=MA(C,N1);
A2:=MA(C,N2);
A3:=MA(C,N3);
A4:=MA(C,N4);
COUNT(A1< A2 AND A2< A3 AND A3< A4,3);
工具箱
【 · 發(fā)布:于瑤 2004-10-05 22:35 】
0033--N日均線向下
AA:=MA(C,N);
BB:=REF(AA,1);
AA< BB
工具箱
【 · 發(fā)布:于瑤 2004-10-05 22:35 】
0034--N日均線向上
AA:=MA(C,N);
BB:=REF(AA,1);
AA>BB
工具箱
【 · 發(fā)布:于瑤 2004-10-05 22:38 】
0035--N日均線走平
AA:=MA(C,N);
BB:=REF(AA,1);
AA=BB
工具箱
【 · 發(fā)布:于瑤 2004-10-05 22:38 】
0036--向前N日至M日出現(xiàn)過均線死叉（P1< P2）
AA:=MA(C,P1);
BB:=MA(C,P2);
CC:=REF(CROSS(BB,AA),N);
COUNT(CC,M);
工具箱
【 · 發(fā)布:于瑤 2004-10-05 22:39 】
0037--今日成交量大于N日以來的均量
VOL>MA(VOL,N);
工具箱
【 · 發(fā)布:于瑤 2004-10-05 22:39 】
0038--低位密集
A1:=COST(85);
A2:=COST(15);
A3:=A1-A2;
A4:=(A1+A2)/2;
A5:=A3/A4*100<10;
B1:=HHV(H,120);
B2:=LLV(L,120);
B3:=B1-B2;
B4:=(A4-B2)< B3/2;
A5 AND B4;
工具箱
【 · 發(fā)布:于瑤 2004-10-05 22:39 】
0039--換手率
VOL/CAPITAL*100;
工具箱
【 · 發(fā)布:于瑤 2004-10-05 22:40 】
0040--N日盈虧
V1:=VOL/SUM(VOL,N);
V2:=DMA(CLOSE,V1);
V3:(CLOSE-V2)/V2*100;
工具箱
【 · 發(fā)布:于瑤 2004-10-05 22:40 】
0041--曲線疊加
指標(biāo)線的疊加，是為了方便觀看和比較，沒什么其他的意義。
一、對指標(biāo)曲線的變化幅度放大
此法，一線變形，另一線不變，但變形線的走勢與原線完全相似。
舉例：C疊加V
BC:=HHV(C,N)-LLV(C,N);//N一般取常用主圖上的K線數(shù)量
BV:=HHV(V,N);
BI:=BC/BV;//疊加比
B:=BI[DATACOUNT];//最后一根K線的疊加比，保證疊加比前后統(tǒng)一
成交量:V,VOLSTICK;
F:=C/REF(C,1);
JC:=REF(C,1)*(1+A*F)*B/A;//A－放大倍數(shù)，將C的漲跌幅度F放大
JL:=LLV(JC,N);//平移量。請去掉JC句的＝看JL的作用
收盤價(jià):C,LINETHICK0,COLORYELLOW;//只顯示數(shù)值，不畫線
PARTLINE(C>0,JC-JL[DATACOUNT]),COLORYELLOW;//收盤價(jià)趨勢線，只畫線，不顯示數(shù)值
通式：
曲線X疊加曲線Y
BX:=HHV(X,N)-LLV(X,N);
BY:=HHV(Y,N)-LLV(Y,N);
BI:=BX/BY;
B:=BI[DATACOUNT];
FX:=X/REF(X,1);
JX:=REF(X,1)*(1+A*FX)*B/A;
XL:=LLV(JX,N);
曲線Y:Y;
曲線X:X,LINETHICK0;//曲線X的值
PARTLINE(C,JX-XL[DATACOUNT]);//曲線X的線
二、百分比疊加
把兩曲線的波動(dòng)幅度劃成百分比進(jìn)行疊加
此法，兩線都變形，但走勢都與原線完全相似。
舉例：C疊加V
HV:=HHV(V,N);
DV:=HV[DATACOUNT];
BV:=100/DV;
V*BV,VOLSTICK;
HC:=HHV(C,N);
LC:=LLV(C,N);
BC:=100/(HC[DATACOUNT]-LC[DATACOUNT]);
(C-LC[DATACOUNT])*BC;
通式一：
曲線X，曲線Y
XH:=HHV(X,N);
XL:=LLV(X,N);
XDH:=XH[DATACOUNT];
XDL:=XL[DATACOUNT];
BX:=100/(XDH-XDL);
曲線X:(X-XDL)*BX;
YH:=HHV(Y,N);
YL:=LLV(Y,N);
YDH:=YH[DATACOUNT];
YDL:=YL[DATACOUNT];
BY:=100/(YDH-YDL);
曲線Y:(Y-YDL)*BY;
通式二：
X曲線+Y曲線
N:=SYSPARAM(3)-SYSPARAM(2);
X:=.........; {.........為X曲線定義}
XH:=HHV(X,N);
XL:=LLV(X,N);
XDH:=XH[SYSPARAM(3)];
XDL:=XL[SYSPARAM(3)];
BX:=100/(XDH-XDL);
曲線X:(X-XDL)*BX;
Y:=.........;{.........為Y曲線定義}
YH:=HHV(Y,N);
YL:=LLV(Y,N);
YDH:=YH[SYSPARAM(3)];
YDL:=YL[SYSPARAM(3)];
BY:=100/(YDH-YDL);
曲線Y:(Y-YDL)*BY;
三、固定位置疊加
此法應(yīng)用不多，僅舉例。
例一：
主圖成交量(V疊加C)
{M:960,1,2000}
R0:=M/1000;R:=(L-R0*SYSPARAM(5))/V;
R1:=LLV(R,SYSPARAM(3)-SYSPARAM(2));R2:=R1[SYSPARAM(3)];
R3:=LLV(L-R2*V,SYSPARAM(3)-SYSPARAM(2));
R4:=R3[SYSPARAM(3)];R5:=(R2*V+R4)*0.995;
STICKLINE(C>=REF(C,1),R5,R0*SYSPARAM(5),6,1)COLORRED;
STICKLINE(C< REF(C,1),R5,R0*SYSPARAM(5),6,0)COLORCYAN;
PARTLINE(V>=0,R0*SYSPARAM(5)) COLORWHITE;
PARTLINE(R5>0,MA(R5,5));
PARTLINE(R5>0,MA(R5,10));
PARTLINE(R5>0,MA(R5,20));
例二：
INPUT:N(10,2,999);
M:=SYSPARAM(3)-SYSPARAM(2);
X:=C;
Y:=SUM(IF(CLOSE>REF(CLOSE,1),VOL/CAPITAL,IF(CLOSE< REF(CLOSE,1),-VOL/CAPITAL,0)),0);
XH:=HHV(X,M); XL:=LLV(X,M); XDH:=XH[SYSPARAM(3)]; XDL:=XL[SYSPARAM(3)];
BX:=100/(XDH-XDL);
收盤:C,LINETHICK0,;
收盤↑:PARTLINE(X>REF(X,1),(X-XDL)*BX),COLORRED;
收盤↓:PARTLINE(X< REF(X,1),(X-XDL)*BX),COLORCYAN;
YH:=HHV(Y,M); YL:=LLV(Y,M); YDH:=YH[SYSPARAM(3)]; YDL:=YL[SYSPARAM(3)];
BY:=100/(YDH-YDL);
TY:=(Y-YDL)*BY;
OBV值:Y*1000,LINETHICK0,COLOR007BFF;
OBV線↑:PARTLINE(Y>REF(Y,1),(Y-YDL)*BY),COLORYELLOW;
OBV線↓:PARTLINE(Y< REF(Y,1),(Y-YDL)*BY),COLOR009F00;
A1:=REF(TY,N)=HHV(TY,2*N+1); B1:=FILTER(A1,N); C1:=BACKSET(B1,N+1); HD:=FILTER(C1,N);
A2:=REF(TY,N)=LLV(TY,2*N+1); B2:=FILTER(A2,N); C2:=BACKSET(B2,N+1); LD:=FILTER(C2,N);
AA:=REF(TY,BARSLAST(HD)); BB:=REF(TY,BARSLAST(LD));A1:=REF(Y,BARSLAST(HD))*1000; B1:=REF(Y,BARSLAST(LD))*1000;
T1:=BARSLAST(HD)< BARSLAST(LD) AND NOT(HD) ;
T2:=BARSLAST(HD)>BARSLAST(LD) AND NOT(LD);
PARTLINE(T1,AA),COLORMAGENTA,LINETHICK2;
PARTLINE(T2,BB),COLORGREEN,LINETHICK2;
DRAWNUMBER(T1=0 AND REF(T1,1)>0,REF(AA,1)+0.1,A1,2);
DRAWNUMBER(T2=0 AND REF(T2,1)>0,REF(BB,1)+0.1,B1,2);
DRAWNUMBER(ISLASTBAR AND T1>0,REF(AA,1)+0.1,A1,2),COLORYELLOW;
DRAWNUMBER(ISLASTBAR AND T2>0,REF(BB,1)+0.1,B1,2),COLORMAGENTA;
工具箱
【 · 發(fā)布:于瑤 2004-10-05 22:41 】
0042--均線變色
MA05:MA(CLOSE,5);
MA30:MA(CLOSE,30);
IF(MA05< MA30,MA05,MA30),COLORGREEN;
IF(MA05< MA30,MA30,MA05),COLORRED;
IF(MA05>MA30,MA30,MA30),COLORBLUE;
DRAWICON(CROSS(MA05,MA30),L*0.98,4);
DRAWICON(CROSS(MA30,MA05),H*1.02,5);
工具箱
【 · 發(fā)布:于瑤 2004-10-07 15:24 】
0055--底背離
LLV(L,60)=L) AND NOT(LLV(DEA,60)=DEA);
工具箱
【 · 發(fā)布:于瑤 2004-10-07 15:25 】
0056--頂背離
HHV(H,60)=H) AND NOT(HHV(DEA,60)=DEA);
工具箱
【 · 發(fā)布:于瑤 2004-10-07 15:25 】
0057--N次金叉、死叉
0軸上二次金叉
COUNT(CROSS(DIF,DEA) AND DEA>0,20)=2 AND CROSS(DIF,DEA) AND
DEA>0;
0軸上三次金叉
COUNT(CROSS(DIF,DEA) AND DEA>0,20)=3 AND CROSS(DIF,DEA) AND
DEA>0;
0軸上四次金叉
COUNT(CROSS(DIF,DEA) AND DEA>0,20)=4 AND CROSS(DIF,DEA) AND DEA>0;
二次金叉
EXPLAIN(COUNT(CROSS(DIF,DEA),20)=2 AND CROSS(DIF,DEA);
二次死叉
COUNT(CROSS(DEA,DIF),20)=2 AND CROSS(DEA,DIF);
工具箱
【 · 發(fā)布:于瑤 2004-10-08 20:57 】
0058--5分鐘副圖顯示15分鐘K線
建公式:0015
C15:CLOSE;
O15:OPEN;
H15:HIGH;
L15:LOW;
建公式:十五K線
C15:="0015.C15#MIN15";
O15:="0015.O15#MIN15";
H15:="0015.H15#MIN15";
L15:="0015.L15#MIN15";
TI:=OPENMINUTES(TIME)=10 OR OPENMINUTES(TIME)=25 OR OPENMINUTES(TIME)=40 OR OPENMINUTES(TIME)=55 OR OPENMINUTES(TIME)=70 OR OPENMINUTES(TIME)=85 OR OPENMINUTES(TIME)=100 OR OPENMINUTES(TIME)=115 OR OPENMINUTES(TIME)=130 OR OPENMINUTES(TIME)=145 OR OPENMINUTES(TIME)=160 OR OPENMINUTES(TIME)=175 OR OPENMINUTES(TIME)=190 OR OPENMINUTES(TIME)=205 OR OPENMINUTES(TIME)=220 OR OPENMINUTES(TIME)=235;
HH15:=IF(TI,H15,C15);
LL15:=IF(TI,L15,C15);
STICKLINE(C15>O15,C15,O15,10,0),COLORRED;
STICKLINE(C15>O15 AND H15>C15,HH15,C15,0.1,0),COLORRED;
STICKLINE(C15>O15 AND O15>L15,O15,LL15,0.1,0),COLORRED;
STICKLINE(C15<=O15,C15,O15,10,0),COLORGREEN;
STICKLINE(C15<=O15 AND C15>L15,C15,LL15,0.1,0),COLORGREEN;
STICKLINE(C15<=O15 AND H15>O15,HH15,O15,0.1,0),COLORGREEN;
注：以大陸股市為例，四小時(shí)，其他市場如超過四小時(shí)，可在中間語句“TI:=”中以15為系數(shù)順序加足，如：OR 250 OR 265……等等。
工具箱
【 · 發(fā)布:于瑤 2004-10-08 20:58 】
0059--移動(dòng)成本
不知道函數(shù)算法，計(jì)算誤差在所難免。調(diào)整參數(shù)“％”可看到不同的移動(dòng)成本。
///籌碼%
INPUT:%(90,1,100);
A:=AMOUNT/V/100;
成本:FLOOR(COST(50-%/2)*100)/100,COLORYELLOW,LINETHICK0;
～:CEILING(COST(50+%/2)*100)/100,COLORYELLOW,LINETHICK0;
集中度:INTPART((～-成本)/(～+成本)*1000)/10,COLORGREEN;
平均成本:ROUND(COST(50)*100)/100,LINETHICK0;
穿透力:(WINNER(C)-REF(WINNER(C),1))/V*CAPITAL,LINETHICK0;//計(jì)算誤差大
//穿透力2:(WINNER(C)-WINNER(O))/V*CAPITAL,LINETHICK0;//這一寫法還是誤差大
獲利比例:ROUND(WINNER(C)*1000)/10,LINETHICK0;
0059--移動(dòng)成本
不知道函數(shù)算法，計(jì)算誤差在所難免。調(diào)整參數(shù)“％”可看到不同的移動(dòng)成本。
///籌碼%
INPUT:%(90,1,100);
A:=AMOUNT/V/100;
成本:FLOOR(COST(50-%/2)*100)/100,COLORYELLOW,LINETHICK0;
～:CEILING(COST(50+%/2)*100)/100,COLORYELLOW,LINETHICK0;
集中度:INTPART((～-成本)/(～+成本)*1000)/10,COLORGREEN;
平均成本:ROUND(COST(50)*100)/100,LINETHICK0;
穿透力:(WINNER(C)-REF(WINNER(C),1))/V*CAPITAL,LINETHICK0;//計(jì)算誤差大
//穿透力2:(WINNER(C)-WINNER(O))/V*CAPITAL,LINETHICK0;//這一寫法還是誤差大
獲利比例:ROUND(WINNER(C)*1000)/10,LINETHICK0;
工具箱
【 · 發(fā)布:于瑤 2004-10-08 20:59 】
0060--妙用SUMBARS()函數(shù)
SUMBARS(X,N)
函數(shù)的用法如下：
向前累加到指定值到現(xiàn)在的周期數(shù)。
用法:
SUMBARS(X,A)
將X向前累加直到大于等于A,返回這個(gè)區(qū)間的周期數(shù)
例如:
SUMBARS(VOL,CAPITAL)
1、設(shè)計(jì)一個(gè)指標(biāo)，計(jì)算當(dāng)日成交量是幾天內(nèi)的最高成交量？
2、設(shè)計(jì)一個(gè)指標(biāo)，計(jì)算當(dāng)日最高價(jià)是幾天內(nèi)的最高價(jià)？
提示：直接用HHV()函數(shù)無法得到正確結(jié)果。
例一：
B:=HHV(H,0);
A:=IF(BARPOS=1,B[DATACOUNT]*1.2,H);
價(jià):SUMBARS(REF(A,1)-A,0);
U:=HHV(V,0);
S:=IF(BARPOS=1,U[DATACOUNT]*1.2,V);
量:SUMBARS(REF(S,1)-S,0);
或：
VH:=HHV(VOL,0);
FV:=IF(BARPOS=1,VH[DATACOUNT]*1.2,VOL); //VH[DATACOUNT]是歷史最高成交量
量創(chuàng)新高周期數(shù):SUMBARS(REF(FV,1)-FV,0);
{這里的關(guān)鍵是 REF(FV,1)-FV ，想想看寫成 FV-REF(FV,1) 行不行？}
另一種寫法：
VH:=HHV(VOL,0);
FV:=VOL;
FV[1]:=VH[DATACOUNT]*1.2; //VH[DATACOUNT]是歷史最高成交量
量創(chuàng)新高周期數(shù):SUMBARS(REF(FV,1)-FV,0);
{這里的關(guān)鍵是 REF(FV,1)-FV ，想想看寫成 FV-REF(FV,1) 行不行？}
代碼已經(jīng)成功了，原理是什么呢？
假設(shè)某日成交量是3日內(nèi)的最大成交量，則必有：
REF(VOL,3)-VOL>=0
等價(jià)于：
(REF(VOL,3)-REF(VOL,2))+(REF(VOL,2)-REF(VOL,1))+(REF(VOL,1)-VOL) >=0
意思就是說，“昨成交量與今成交量之差”逐日累加，直到某日累加和大于等于0，則這之間的天數(shù)，就是所要求的日數(shù)。
我們再來看看SUMBARS()函數(shù)的含義：
SUMBARS(X,A):將X向前累加直到大于等于A,返回這個(gè)區(qū)間的周期數(shù)。
顯然上面的式子：
(REF(VOL,3)-REF(VOL,2))+(REF(VOL,2)-REF(VOL,1))+(REF(VOL,1)-VOL)>=0
可以寫成：
SUMBARS(REF(VOL,1)-VOL, 0);
為何第1周期的成交量要替換成比所有成交量都大的數(shù)值？最后，再來思考一個(gè)問題，把題目中的求“最大”，改成求“最小”，即多少天內(nèi)是最小的？
例二：
B:=HHV(H,0);
A:=IF(BARPOS=1,9999,H);
Z:SUMBARS(REF(A,1)-A,0);
DRAWNUMBER(BARPOS=SYSPARAM(1),1,Z,0)ALIGN4,COLORWHITE;
U:=HHV(V,0);
S:=IF(BARPOS=1,999999999999,V)
Y:SUMBARS(REF(S,1)-S,0);
DRAWNUMBER(BARPOS=SYSPARAM(1),1,Y,0)ALIGN3,COLORYELLOW;
例三：
HH:=IF(BARSCOUNT(C)=1,9999,H);
ZH:SUMBARS(REF(HH,1)-HH,0);//價(jià)創(chuàng)了N周期新高
VH:=IF(BARSCOUNT(C)=1,99999999,V);
HV:SUMBARS(REF(VH,1)-VH,0);//量創(chuàng)了N周期新高
LL:=IF(BARSCOUNT(C)=1,0,L);
ZL:SUMBARS(LL-REF(LL,1),0);//價(jià)創(chuàng)了N周期新低
VL:=IF(BARSCOUNT(C)=1,0,V);
LV:SUMBARS(VL-REF(VL,1),0);//量創(chuàng)了N周期新低
附注：
用99999999等具體數(shù)值，最好是盡可能大的數(shù)值（比如單精數(shù)的上限），否則仍有可能無法全部完成計(jì)算，比如上證指數(shù)的年線，成交量最大時(shí)，仍然超過了99999999。
倒數(shù)第6天的最高價(jià)格怎么表示？
FH:=HIGH;
FH[DATACOUNT-5]; //倒數(shù)第6天的最高價(jià)格。
[DATACOUNT]
返回K線的數(shù)量，即總共有多少根K線。
工具箱
【 · 發(fā)布:于瑤 2004-10-09 01:52 】
0061--取得K線的序號
取得K線的序號，正序有下面幾種方法：(從1數(shù)起)
BARPOS;
SX:BARSCOUNT(CLOSE);
SY:SUM(1,0);
DATACOUNT;{不隨光標(biāo)變動(dòng)，只顯示最后K線序號}
逆序可用下列方法取得：(從1數(shù)起)
(DATACOUNT-BARPOS)+1;
(DATACOUNT-BARSCOUNT(CLOSE))+1;
(DATACOUNT-SUM(1,0))+1;
工具箱
【 · 發(fā)布:于瑤 2004-10-09 01:53 】
0062--變量宣告
指定敘述：經(jīng)過指定宣告后，飛狐才認(rèn)識AA、BB、CC，否則會(huì)出現(xiàn)"未定義的標(biāo)示符號"。所謂"定義"，程序語言的用語，就叫做"變量宣告"。
AA:OPEN;{宣告OPEN，指定給AA→輸出的表達(dá)式}
BB:HIGH,LINETHICK0;{宣告HIGH，指定給BB→輸出的表達(dá)式→秀數(shù)值但不秀線圖}
CC:=CLOSE;{宣告CLOSE，指定給CC→不輸出的表達(dá)式→不秀數(shù)值也不秀線圖}
DD:(AA+BB+CC)/3;{;分號，告訴程序要換行執(zhí)行了}
EE:=(AA+CC)/2;
PARTLINE(CLOSE>0,EE);{秀線圖但不秀數(shù)值}
注：{ }大括號內(nèi)或在//后面，可用來輸入公式批注。
工具箱
【 · 發(fā)布:于瑤 2004-10-09 01:53 】
0063--跨周期引用數(shù)據(jù)
(一)指針線公式的運(yùn)算，大部份都是代入開、高、低、收、量等數(shù)據(jù)去運(yùn)算的。
(二)開、高、低、收、量又分成下面四種型式出現(xiàn)：
開、高、低、收、量(基本的日K線數(shù)據(jù))
開、高、低、收、量(周K線數(shù)據(jù))
開、高、低、收、量(月K線數(shù)據(jù))
開、高、低、收、量(年K線數(shù)據(jù))
(三)所以當(dāng)指針線公式運(yùn)算，要代入下面數(shù)據(jù)時(shí)：
開、高、低、收、量(周K線數(shù)據(jù))
開、高、低、收、量(月K線數(shù)據(jù))
#WEEK 和 #MONTH 就會(huì)派上用場。
(四)舉例：
公式A.建立一個(gè)專門被用來引用(QUOTE)的公式區(qū)。
公式名稱：QU
A1:(OPEN+HIGH+LOW+CLOSE)/4;
說明：上面公式的運(yùn)算，是代入開、高、低、收(當(dāng)前周期K線數(shù)據(jù))運(yùn)算的。
公式B.
公式名稱：AA
AA:"QU.A1#WEEK";
說明：將下面公式的運(yùn)算，代入開、高、低、收(周K線數(shù)據(jù))運(yùn)算。
(OPEN+HIGH+LOW+CLOSE) / 4
公式C.
公式名稱：BB
BB:"QU.A1#MONTH";
說明：將下面公式的運(yùn)算，代入開、高、低、收(月K線數(shù)據(jù))運(yùn)算。
(OPEN+HIGH+LOW+CLOSE)/4
附注：
可供引用的周期類型有：
MIN1，MIN5，MIN15，MIN30，MIN60，DAY，WEEK，MONTH
分別表示將1，5，15，30，60分鐘K線數(shù)據(jù)，以及日，周，月K線數(shù)據(jù)，代入被引用的公式，進(jìn)行運(yùn)算。
意義：
可將大周期內(nèi)跑的數(shù)據(jù)，引用到小周期內(nèi)來跑。將小周期內(nèi)跑的數(shù)據(jù)，引用到大周期內(nèi)來跑，就會(huì)有問題，因?yàn)闀r(shí)間橫坐標(biāo)不一樣了。
公式(1)：先建立即將被引用的表達(dá)式
將公式建立在：技術(shù)指針 ( ●主圖疊加 ○主圖 )
公式名稱：NH
AA:=HIGH< REF(HIGH,1);{不輸出的表達(dá)式，如果被引用還是會(huì)變成不輸出的表達(dá)式}
BB:=BARSLAST(AA=1);
CC:REF(HIGH,BB); {輸出的表達(dá)式，如果被引用還是會(huì)變成輸出的表達(dá)式}
說明：
上面公式的運(yùn)算，是以當(dāng)周期時(shí)間數(shù)列數(shù)據(jù)運(yùn)算的。
公式(2)：
將公式建立在：技術(shù)指針 ( ●主圖疊加 ○主圖 )
公式名稱：NHH
AA:"NH.AA#WEEK";{不輸出的表達(dá)式}
BB:"NH.BB#WEEK";
CC:"NH.CC#WEEK";{輸出的表達(dá)式}
DRAWNUMBER(ISLASTBAR,CC,CC,2);
說明：
上面公式的運(yùn)算，是以周周期時(shí)間數(shù)列數(shù)據(jù)運(yùn)算的。
工具箱
【 · 發(fā)布:于瑤 2004-10-09 01:54 】
0064--未來數(shù)據(jù)、未知數(shù)據(jù)
寫公式，首先要對已知數(shù)據(jù)(過去式)、未知數(shù)據(jù)(未完成式、現(xiàn)在進(jìn)行式)有通盤的認(rèn)知。
可將"未來"分為兩種情況：
1、實(shí)時(shí)行情中：在一根K線。
以實(shí)時(shí)行情中的當(dāng)前日K線為例。除了O之外，其它H、L、C全有未來之嫌。因?yàn)樵谑毡P之前，拉高、打壓是司空見慣的事，誰也不能保證H、L不會(huì)創(chuàng)出當(dāng)天的新高和新低，更不用說C了。又如日線周期公式"C>REF(C,1);"，前一分鐘信號成立，后一分鐘可能信號就不成立了。另外，如引用了周K和月K數(shù)據(jù)，因?yàn)楫?dāng)前周K和月K還在變動(dòng)之中，所以也是未來資料。
2、盤后中：在多根K線。
因?yàn)樵诒P后，日K中的四大要素O、H、L、C就沒有未來之可能了。在盤后，除了周五之外，引用的周K指針也是未來數(shù)據(jù)。除了在月末，引用的月K指針也是未來數(shù)據(jù)。
總而言之，指針公式就分這兩種：
線圖信號的確定→全都用已知數(shù)據(jù)(過去式)來決定。
線圖信號的確定→有用到未知數(shù)據(jù)(未完成式、現(xiàn)在進(jìn)行式)來決定。
ZIG函數(shù)
ZX:ZIG(CLOSE,8);
最近這次峰點(diǎn)、谷點(diǎn)的確定，也常處在未完成式的狀態(tài)中。
打個(gè)比喻，線圖信號的確定→有用到未知數(shù)據(jù)(未完成式、現(xiàn)在進(jìn)行式)，例如，在實(shí)時(shí)盤中一根日K線的收盤價(jià)變來變?nèi)?，指針線圖當(dāng)然隨之而起舞。
ZIG函數(shù)只是把格局放大，N的日K組合而成的一根多日K線，這一根多日K線的收盤價(jià)變來變?nèi)ィ羔樉€圖當(dāng)然隨之而起舞。
工具箱
【 · 發(fā)布:于瑤 2004-10-09 01:55 】
0065--主圖KD
在主圖上，坐標(biāo)是以K線的價(jià)格為主。如何將在0與100中游走的KD指針附加上去，這是寫作指針的基本邏輯觀念的運(yùn)用。
PARAM#1( N，9，2，100 )
PARAM#2( M1，3，1，40 )
PARAM#3( M2，3，1，40 )
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100 LINETHICK0;{:=運(yùn)算過程不顯示值與圖}
K:SMA(RSV,3,1),LINETHICK0,COLORWHITE;{LINETHICK0只顯值不顯圖}
D:SMA(K,3,1),LINETHICK0,COLORYELLOW;
HH:=SYSPARAM(4);{主圖可見K線最高價(jià)}
LL:=SYSPARAM(5);{主圖可見K線最低價(jià)}
KK:=K/100*(HH-LL)+LL;
DD:=D/100*(HH-LL)+LL;
PARTLINE(1=1,KK),COLORWHITE; {條件成立時(shí)，則顯示圖線形}
PARTLINE(C>0,DD),COLORYELLOW;
C;{顯示收盤價(jià)的值與圖線形}
PARTLINE(C>=REF(C,1),C),COLORRED;{顯示收盤價(jià)的圖改成漲紅跌綠聯(lián)機(jī)圖}
PARTLINE(C< REF(C,1),C),COLORGREEN;
工具箱 0066--描繪K線
例一：普通
將下列公式建立在：技術(shù)指針 ( ○主圖疊加 ●主圖 )
公式名稱：KL
STICKLINE( ISUP , HIGH , LOW , 0.1 , 0 ) , COLORRED ;
STICKLINE( ISUP , CLOSE , OPEN , 8 , 1 ) , COLORRED ;
STICKLINE( ISDOWN , HIGH , LOW , 0.1 , 0 ) , COLORCYAN ;
STICKLINE( ISDOWN , CLOSE , OPEN , 8 , 0 ) , COLORCYAN ;
STICKLINE( ISEQUAL AND C>REF( C , 1 ) , HIGH , LOW , 0.1 , 0 ) , COLORRED ;
STICKLINE( ISEQUAL AND C>REF( C , 1 ) , CLOSE , OPEN , 8 , 0 ) , COLORRED ;
STICKLINE( ISEQUAL AND C<=REF( C , 1 ) , HIGH , LOW , 0.1 , 0 ) , COLORCYAN ;
STICKLINE( ISEQUAL AND C<=REF( C , 1 ) , CLOSE , OPEN , 8 , 0 ) , COLORCYAN ;
X:=BARSCOUNT( CLOSE ) ;
{以下是描繪第一個(gè)交易日的K線，以補(bǔ)前面含蓋的不足}
STICKLINE( ISEQUAL AND X = 1 , HIGH, LOW, 0.1, 0 ) , COLORRED ;
STICKLINE( ISEQUAL AND X = 1 , CLOSE , OPEN , 8 , 0 ) , COLORRED ;
說明：
ISUP函數(shù)：相當(dāng)于 IF( CLOSE>OPEN , 1 , 0 )。
ISEQUAL函數(shù)：相當(dāng)于 IF( CLOSE=OPEN , 1 , 0 )。
ISDOWN函數(shù)：相當(dāng)于 IF( CLOSE < OPEN , 1 , 0 )。
STICKLINE函數(shù)，畫出來的對象有重疊覆蓋性：→后畫的對象可覆蓋先畫的對象。
例二：配色
STICKLINE( ISUP , HIGH , LOW , 0.1 , 0 ),COLOR04FEFC ;
STICKLINE( ISUP , CLOSE , OPEN , 8 , 0 ),COLOR0466FC ;
STICKLINE( ISUP , CLOSE , OPEN , 3 , 0 ),COLOR04FEFC ;
STICKLINE( ISDOWN , HIGH , LOW , 0.1 , 0 ),COLORFCFE04 ;
STICKLINE( ISDOWN , CLOSE , OPEN , 8 , 0 ),COLORFC6604 ;
STICKLINE( ISDOWN , CLOSE , OPEN , 3 , 0 ),COLORFCFE04 ;
STICKLINE( ISEQUAL AND C>REF( C , 1 ) , HIGH , LOW , 0.1 , 0 ),COLOR04FEFC ;
STICKLINE( ISEQUAL AND C>REF( C , 1 ) , CLOSE , OPEN , 8 , 0 ),COLOR0466FC ;
STICKLINE( ISEQUAL AND C>REF( C , 1 ) , CLOSE , OPEN , 3 , 0 ),COLOR04FEFC ;
STICKLINE( ISEQUAL AND C<=REF( C , 1 ) , HIGH , LOW , 0.1 , 0 ),COLORFCFE04 ;
STICKLINE( ISEQUAL AND C<=REF( C , 1 ) , CLOSE , OPEN , 8 , 0 ),COLORFC6604 ;
STICKLINE( ISEQUAL AND C<=REF( C , 1 ) , CLOSE , OPEN , 3 , 0 ),COLORFCFE04 ;
X:=BARSCOUNT( CLOSE ) ;
{以下是描繪第一個(gè)交易日的K線，以補(bǔ)前面含蓋的不足}
STICKLINE( ISEQUAL AND X = 1 , HIGH, LOW, 0.1, 0 ),COLOR04FEFC ;
STICKLINE( ISEQUAL AND X = 1 , CLOSE , OPEN , 8 , 1 ),COLOR0466FC ;
STICKLINE( ISEQUAL AND X = 1 , CLOSE , OPEN , 3 , 1 ),COLOR04FEFC ;
工具箱
【 · 發(fā)布:于瑤 2004-10-09 01:56 】
0067--分時(shí)K線當(dāng)天K線序號
范例：開盤第一根分時(shí)K線，指定一個(gè)值=1給它，其它為0。
XA:REF(DATE,1)<>DATE, STICK;
范例：每天的分時(shí)K線，指定它的當(dāng)天K線序號給它
XA:=REF(DATE,1)<>DATE, STICK;
XB:BARSLAST(XA=1) + 1 ,STICK;
應(yīng)用：每天在分時(shí)K線，累計(jì)成交張數(shù)
XA:=REF(DATE,1)<>DATE , STICK;
XB:=BARSLAST(XA=1) + 1 ,STICK;
SV:SUM( VOL , XB ) ;
范例：標(biāo)記今天分時(shí)K線的今天K線序號。過了午夜12點(diǎn)，就又要等早盤開盤后序號數(shù)字才會(huì)出現(xiàn)
XA:=CURRENTDATE=DATE ;
XB:=REF(XA , 1)<>XA ;
XC:HHVBARS(XB , 0) + XA ;
應(yīng)用：13均線今天當(dāng)下最后數(shù)值向后延申，畫平臺(tái)線。
XA:=CURRENTDATE=DATE ;
XB:=REF(XA , 1)<>XA ;
XC:=HHVBARS(XB , 0) + XA ;
XD:=MA(C,13);
XE:=REFX(XD , 300);
XF:IF(XC>=0 , XE , 0) ,LINETHICK0,COLOR99FFFF;
PARTLINE(XC>=1 , XF) ,COLOR99FFFF;
工具箱
【 · 發(fā)布:于瑤 2004-10-09 01:57 】
0068--系統(tǒng)參數(shù)函數(shù)
這組函數(shù)，應(yīng)用在取得當(dāng)前可視主圖區(qū)內(nèi)的一些數(shù)字信息，如下所示：
1.當(dāng)前十字光標(biāo)所在位置，那根K線的序號；
2.當(dāng)前可視主圖區(qū)，最初那根K線的序號；
3.當(dāng)前可視主圖區(qū)，最后那根K線的序號；
4.當(dāng)前可視主圖區(qū)，最高價(jià)；
5.當(dāng)前可視主圖區(qū)，最低價(jià)。
注：但須調(diào)出十字光標(biāo)后，這組函數(shù)才能發(fā)生作用。否則回傳的值是不確定的。
SYSPARAM(1)
SYSPARAM(2)
SYSPARAM(3)
SYSPARAM(4)
SYSPARAM(5)
函數(shù)：SYSPARAM(1)
說明： 回傳當(dāng)前 十字光標(biāo)所在位置那根K線的序號
函數(shù)：SYSPARAM(2)
說明： 回傳當(dāng)前可視主圖區(qū) 最初那根K線的序號
函數(shù)：SYSPARAM(3)
說明： 回傳當(dāng)前可視主圖區(qū) 最后那根K線的序號
函數(shù)：SYSPARAM(4)
說明： 回傳當(dāng)前可視主圖區(qū) 最高價(jià)
函數(shù)：SYSPARAM(5)
說明： 回傳當(dāng)前可視主圖區(qū) 最低價(jià)
范例：
將公式建立在：技術(shù)指針 ( ●主圖疊加 ○主圖 )
SS:=SYSPARAM( 1 ) ;
DD:=SUM( 1 , 0 ) ;
CC:CLOSE * 1.07 , LINETHICK0 , COLORYELLOW ;
PARTLINE( SS>=DD , CC ) , COLORYELLOW ;
注：
DD:SUM( 1 , 0 ) ;
SS:SYSPARAM( 1 ) ;
上面兩者，顯然有明顯的不同之處。
1.DD是一組變量型時(shí)間數(shù)列，代表K線的序號。
2.SS是隱含有N組常數(shù)型時(shí)間數(shù)列(N=這支股票的K線總數(shù))。
DD:SUM(1,0)
以數(shù)學(xué)的二維空間F(X)=Y表示：Y=X
SS:SYSPARAM(1)
以數(shù)學(xué)的二維空間F(X)=Y表示，其中A屬正整數(shù)：Y=A
SUM(1,0)=SYSPARAM(1)意指，下面兩條線交叉成立的那一點(diǎn)：
Y=X
Y=A
范例：
MA1:=MA(CLOSE,5);
MA2:=MA(CLOSE,13);
XA:=CROSS(MA1,MA2) ;
XB:IF(XA=1,SUM(1,0),0);{條件成立時(shí)回傳它的K線序號}
工具箱
【 · 發(fā)布:于瑤 2004-10-09 21:32 】
0069--概率統(tǒng)計(jì)
COUNT，計(jì)數(shù)。SUM，總數(shù)、和。
當(dāng)數(shù)組為邏輯運(yùn)算判斷的結(jié)果時(shí)，COUNT和SUM的返回值是一樣的。一般習(xí)慣上，對于邏輯運(yùn)算信號，用COUNT統(tǒng)計(jì)，返回其它數(shù)值的，用SUM統(tǒng)計(jì)。
當(dāng)COUNT統(tǒng)計(jì)一般數(shù)值時(shí)，數(shù)組大于等于1時(shí)，計(jì)入；小于1時(shí)，不計(jì)入。這兩個(gè)函數(shù)，主要用于統(tǒng)計(jì)。
用COUNT(CROSS(MA(C,5),MA(C,10)),0);就可以統(tǒng)計(jì)出全部的五天均線上穿十天均線的金叉數(shù)。
用SUM(CROSS(MA(C,5),MA(C,10)),0);和以上得出的結(jié)果應(yīng)該是一樣的。
股市的不隨機(jī)規(guī)律，隱藏在統(tǒng)計(jì)概率之中。用這兩個(gè)函數(shù)，可以統(tǒng)計(jì)很多概率性的規(guī)律。
比如，以兩天的收盤價(jià)相比，昨天是下跌的，今天的下跌的概率是多少？
A:=C< REF(C,1);
B:=REF(A,1) AND C>REF(C,1);{昨天下跌，今天上漲}
D:=REF(A,1) AND C=REF(C,1);{昨天下跌，今天平盤}
E:=REF(A,1) AND C< REF(C,1);{昨天下跌，今天下跌}
F:=COUNT(B,0)+COUNT(D,0)+COUNT(E,0);
上升概率:100*COUNT(B,0)/F;
下跌概率:100*COUNT(E,0)/F;
平盤概率:100*COUNT(D,0)/F;
從兩市指數(shù)看，昨天下跌，今天下跌的概率始終大于50%。那么連跌兩天之后，第三天收盤的各種概率是多少？
A:=C< REF(C,1) AND REF(C,1)< REF(C,2);
B:=REF(A,1) AND C>REF(C,1);{前兩天下跌，今天上漲}
D:=REF(A,1) AND C=REF(C,1);{前兩天下跌，今天平盤}
E:=REF(A,1) AND C< REF(C,1);{前兩天下跌，今天下跌}
F:=COUNT(B,0)+COUNT(D,0)+COUNT(E,0);
上升概率:100*COUNT(B,0)/F;
下跌概率:100*COUNT(E,0)/F;
平盤概率:100*COUNT(D,0)/F;
從指數(shù)的輸出看，概率更明顯了。連跌三天之后呢？
A:=C< REF(C,1) AND REF(C,1)< REF(C,2) AND REF(C,2)< REF(C,3);
B:=REF(A,1) AND C>REF(C,1);{前三天下跌，今天上漲}
D:=REF(A,1) AND C=REF(C,1);{前三天下跌，今天平盤}
E:=REF(A,1) AND C< REF(C,1);{前三天下跌，今天下跌}
F:=COUNT(B,0)+COUNT(D,0)+COUNT(E,0);
上升概率:100*COUNT(B,0)/F;
下跌概率:100*COUNT(E,0)/F;
平盤概率:100*COUNT(D,0)/F;
規(guī)律就更明顯了。
不要小看這些數(shù)據(jù)。雖然沒有有些“高手”做出的成功率達(dá)百分之九十左右的公式那么夸張，但很有意義的。要知道股市中的隨機(jī)因素太多，平衡性很強(qiáng)，稍稍的統(tǒng)計(jì)偏向，足可作為有用的參考。
這只是簡單的例子，用這兩個(gè)函數(shù)，可以做出很多的有用的統(tǒng)計(jì)數(shù)據(jù)。多數(shù)的交易系統(tǒng)的"勝率"，可以由此統(tǒng)計(jì)出來。
統(tǒng)計(jì)：
A:=CROSS(C,MA(C,3));
B:=CROSS(MA(C,3),C);
D:B*(C-REF(C,BARSLAST(A)));
月:SUM(D,20);
季:SUM(D,60);
半:SUM(D,120);
年:SUM(D,250);
總和:SUM(D,0);
工具箱
【 · 發(fā)布:于瑤 2004-10-09 21:48 】
0070--五彩K線常用顏色
黑色 COLORBLACK 藍(lán)色 COLORBLUE
棕色 COLORBROWN 青色 COLORCYAN
灰色 COLORGRAY 綠色 COLORGREEN
晶紅 COLORMAGENTA 紅色 COLORRED
白色 COLORWHITE 黃色 COLORYELLOW
工具箱
【 · 發(fā)布:于瑤 2004-10-09 21:50 】
0071--分析家公式設(shè)定注意事項(xiàng)
參數(shù) 最多四個(gè)參數(shù),每個(gè)有最大和最小及缺省值,須有自己名稱
注釋 用大括號括起來放在被注釋語句之后
公式名稱 由字母或數(shù)字組成,在同類公式中必須唯一,最多九個(gè)字符
中間公式 使用":="來定義名字,不能與系統(tǒng)提供的函數(shù)同名
Param#1-4 對應(yīng)于參數(shù)1-4,大小寫敏感
坐標(biāo)線位置 最多七個(gè),用分號分隔
組合公式設(shè)置 小公式間用分號隔開
繪圖參數(shù)使用 將其插入到指標(biāo)公式的后面,用逗號分隔開
區(qū)分多條指標(biāo)線 在指標(biāo)公式前寫上名稱并加上一個(gè)冒號
指標(biāo)線名字的使用 可以當(dāng)函數(shù)名用
指標(biāo)線繪制的極限 可同圖顯示16條指標(biāo)線
五彩顏色參數(shù)使用 將其插入到指標(biāo)公式的后面,用逗號分隔開
工具箱
【 · 發(fā)布:于瑤 2004-10-09 21:53 】
0072--交易系統(tǒng)公式交易類型
ENTERLONG 多頭買入 ENTERSHORT 空頭買入
EXITLONG 多頭賣出 EXITSHORT 空頭賣出
工具箱
【 · 發(fā)布:于瑤 2004-10-09 21:56 】
0073--可供引用的周期類型
MIN1 1分鐘線 MIN60 60分鐘線
MIN5 5分鐘線 DAY 日線
MIN15 15分鐘線 WEEK 周線
MIN30 30分鐘線 MONTH 月線
工具箱
【 · 發(fā)布:于瑤 2004-10-09 21:59 】
0074--引用表達(dá)式
引用指標(biāo)公式 公式名稱.指標(biāo)線名稱(參數(shù)表)
引用交易系統(tǒng)公式 SYSTEM.公式名稱.交易類型(參數(shù)表)
引用條件選股公式 EXPLORER.公式名稱(參數(shù)表)
跨周期引用公式 各種類型公式名稱#周期類型(參數(shù)表)
引用任意股票的數(shù)據(jù) 股票代碼$數(shù)據(jù)名稱
引用擴(kuò)展數(shù)據(jù) EXTDATA(N) 分析家N=1-11 飛狐N=1-13
引用橫向統(tǒng)計(jì)日線數(shù)據(jù)(1-N) ESTDATA(N)
引用類函數(shù)第二個(gè)變量參數(shù) 類函數(shù)名稱(第一參數(shù),變量名或變量表達(dá)式)
工具箱
【 · 發(fā)布:于瑤 2004-10-09 22:19 】
0075--符號一覽表
符號 名稱 舉例 符號 名稱 舉例
+ 加 X + Y && 并且 X>Y && Y>Z
- 減 X - Y || 或者 X>Y || Y>Z
* 乘 X * Y $ 修飾符號 000014$CLOSE
/ 除 X / Y ( 括號 HIGH/(CLOSE+OPEN)
< 小于 X < Y ) 反括號 HIGH/(CLOSE+OPEN)
> 大于 X > Y , 逗號 MA(Close,3)
<= 小于等于 X <= Y : 輸出 輸出:CLOSE+OPEN
>= 大于等于 X >= Y := 賦值 變量1:=HIGH
= 等于 X = Y " 雙引號 "000014$OPEN"
{} 注釋符號 {注釋部分} . 點(diǎn)號 KDJ.K
// 注釋符號 //注釋部分 ; 分號 A:=CLOSE;
AND 并且 X>Y AND Y>Z # 變周期符號 TMP1:=CLOSE#WEEK
OR 或者 X>Y OR Y>Z ## 變周期前一 VOL##DAY
<> 非 X <> Y ' 單引號 '大陽線'
工具箱
【 · 發(fā)布:于瑤 2004-10-09 22:35 】
0076--橫向統(tǒng)計(jì)
函數(shù)：ESTDATA(N)
描述：取得橫向統(tǒng)計(jì)日線數(shù)據(jù)(1-N)
類別：擴(kuò)展數(shù)據(jù)
參數(shù)：N
說明：在[橫向統(tǒng)計(jì)管理]中定義并計(jì)算數(shù)據(jù)(本函數(shù)僅在日線分析周期有效)。
用基本公式做出的主圖公式和副圖公式，顯示在個(gè)股或指數(shù)中，是縱向的，遍歷當(dāng)時(shí)顯示的個(gè)股或指數(shù)中的每根K線。然后指標(biāo)大小、變化、交叉情況等，都體現(xiàn)在某一個(gè)股或指數(shù)中。甲股和乙股，哪個(gè)KDJ中的K值大？用縱向變量（指標(biāo)），原來就一點(diǎn)招數(shù)都沒有。又比如，兩市A股中，今天有幾只個(gè)股的收盤價(jià)在10日均線之上，用縱向變量（指標(biāo)）也沒有辦法，因?yàn)榭v向變量（指標(biāo)）只能在某一個(gè)股或指數(shù)中才可以比較。而多股間橫向的比較和統(tǒng)計(jì)，是很有參考價(jià)值的。所以，相對于原來的縱向變量（指標(biāo)），就有了橫向變量這一說。
橫向指標(biāo)用在公式中，也是遍歷每根K線的，與一般的基本函數(shù)的遍歷有點(diǎn)不同，因?yàn)樗臄?shù)據(jù)來源不同，是對應(yīng)于每根K線的日子以及哪個(gè)日子中對應(yīng)板塊中的個(gè)股數(shù)和選擇條件等。
橫向統(tǒng)計(jì)涉及全場數(shù)據(jù)的計(jì)算，而且可以增加到數(shù)千項(xiàng)之多，運(yùn)算量驚人，目前無法做到實(shí)時(shí)刷新（動(dòng)態(tài)顯示），只能手工刷新（建議盤后進(jìn)行）。
橫向變量主要用于盤后。要?jiǎng)討B(tài)刷新，目前沒有即時(shí)刷新的設(shè)置，可能考慮到計(jì)算量較大吧。要是不怕麻煩，過幾分鐘就刷新一下（刷新一次，就相當(dāng)于重新計(jì)算一遍），也可以看到"動(dòng)態(tài)"漲跌值排名。
橫向變量在公式中的輸出，與K線的日子有絕對的關(guān)系，與當(dāng)時(shí)顯示的個(gè)股或指數(shù)沒有多大關(guān)系，在某個(gè)股中的輸出和其他任一個(gè)股中的輸出都一樣。
橫向變量所用的統(tǒng)計(jì)方法，是對所選板塊中的個(gè)股或指數(shù)，進(jìn)行全盤的統(tǒng)計(jì)。最近所加的"最大值"、"最小值"是兩個(gè)極值，是對排序頭尾的取值。而要取橫向排序中的第二名、第三名，單用橫向變量目前還做不到。但不排除此功能以后會(huì)開發(fā)出來。
排名名次要用擴(kuò)展數(shù)據(jù)！橫向變量目前做不到。
如果做橫向變量或擴(kuò)展數(shù)據(jù)，在當(dāng)時(shí)選擇的計(jì)算周期如果是日線，則今天刷新，"原本排列"就保存在昨天。橫向變量實(shí)際上即是橫向的，從時(shí)間上又是縱向的。
擴(kuò)展數(shù)據(jù)是橫向的，引用時(shí)從時(shí)間上又是縱向的。
0077--擴(kuò)展數(shù)據(jù)
函數(shù)：EXTDATA(N)
描述：取得日線擴(kuò)展數(shù)據(jù)(1-13); 分析家N取1--11
類別：擴(kuò)展數(shù)據(jù)
參數(shù)：N取1--13
說明：在[擴(kuò)展數(shù)據(jù)管理]中定義并計(jì)算數(shù)據(jù)(本函數(shù)僅在日線分析周期有效)。
有些數(shù)據(jù)，非常重要，可是隨著時(shí)間的推移，就再也找不到了。比如說某個(gè)股一天之中的總成交次數(shù)，又比如說某個(gè)股在上個(gè)月的1號，漲幅排名是第幾？這些信息，要么以后就查不到了，要么在公式中也無法引用。而擴(kuò)展數(shù)據(jù)庫能解決這些問題。擴(kuò)展數(shù)據(jù)庫能夠隨日線保存這些數(shù)據(jù)，而且是計(jì)算好了的結(jié)果，所以引用時(shí)速度也很快。
擴(kuò)展數(shù)據(jù)有兩個(gè)用處：1、保存計(jì)算值。2、保存計(jì)算值的排名結(jié)果。目前飛狐的擴(kuò)展數(shù)據(jù)，可以最多做13個(gè)。太多了好象也沒有多大意思，因?yàn)閿U(kuò)展數(shù)據(jù)計(jì)算歷史數(shù)據(jù)有點(diǎn)慢，而且也較占空間。歷史的數(shù)據(jù)量大，當(dāng)然慢了?？墒怯?jì)算好之后，以后只要更新當(dāng)天的，速度還是較快的。計(jì)算擴(kuò)展數(shù)據(jù)，某個(gè)股，一個(gè)交易日，一次只能得到一個(gè)結(jié)果數(shù)據(jù)，而且所選之指標(biāo)，也應(yīng)該是唯一的。
想保存所有分筆成交記錄？擴(kuò)展數(shù)據(jù)是做不到的。
缺省數(shù)據(jù)：某一天，或者說個(gè)股停盤等原因，沒有計(jì)算結(jié)果，系統(tǒng)就將缺省數(shù)據(jù)保存到擴(kuò)展數(shù)據(jù)庫中。
在進(jìn)行排序時(shí)，有兩種排序方式，一種為0-N自然排序，一種為1-1000歸一化排序，區(qū)別在于：自然排序按自然數(shù)來排列名次，排名在第幾結(jié)果就是幾，第一名，返回0；第二名，返回1；第N名，返回N-1。而歸一化排序時(shí)將排序歸一化到0-1000之間，第一位為0，最后一位為1000，采用公式"排名*1000/參加排名的股票數(shù)"來進(jìn)行計(jì)算。歸一化排序的好處是，不隨股票數(shù)目的增加而對排序結(jié)果有較大的影響。
怎么引用擴(kuò)展數(shù)據(jù)？EXTDATA(N);N指引用第幾組擴(kuò)展數(shù)據(jù)，從1到13。比如把分筆成交次數(shù)的擴(kuò)展數(shù)據(jù)建立在第一組中，引用時(shí)，就用EXTDATA(1);這個(gè)公式，在某個(gè)股中，就輸出此股在當(dāng)天的總成交次數(shù)。擴(kuò)展數(shù)據(jù)，有橫向的性質(zhì)，特別是用排名時(shí)。同時(shí)又是縱向的，只要有數(shù)據(jù)，以前的日子里，也可以返回所得值。而且從理論上說，擴(kuò)展數(shù)據(jù)庫是可以永遠(yuǎn)保存的。由于計(jì)算量較大，目前擴(kuò)展數(shù)據(jù)不支持即時(shí)刷新。不過可以手工刷新。
工具箱
【 · 發(fā)布:于瑤 2004-10-09 22:43 】
0078--峰點(diǎn)公式
為了能找到合適的COND，用于舉例子，先介紹一組概念：
高點(diǎn)：在2N+1根K線中，中間這根K線的H，要大于等于左右N根K線的H。在N+1根K線中，有等高點(diǎn)出現(xiàn)，取最先出現(xiàn)的。
低點(diǎn)：在2N+1根K線中，中間這根K線的L，要小于等于左右N根K線的L。在N+1根K線中，有等低點(diǎn)出現(xiàn)，取最先出現(xiàn)的。
峰點(diǎn)：高點(diǎn)和低點(diǎn)，合稱為峰點(diǎn)。
這個(gè)定義，意合于技術(shù)分析的老祖宗道氏："只要平均指數(shù)的最高點(diǎn)超過了前期的最高點(diǎn)，它就處于牛市時(shí)期；當(dāng)最低點(diǎn)低于前期的最低點(diǎn)時(shí)，它處于熊市時(shí)期。"這里我們撇開向上、向下分形和分形峰狀點(diǎn)等概念，以免把概念復(fù)雜化。
也為了不讓公式一來就過于復(fù)雜，我們先取N為2來做公式。簡介到后面，可以看到，N是可以作為峰點(diǎn)公式的參數(shù)進(jìn)行調(diào)整的。
公式名稱：FENG2
公式說明：供引用
公式內(nèi)容：
{峰點(diǎn)參數(shù)暫定為2}
A:=REF(H,2);{中間K線的最高價(jià)}
B:=A>=REF(H,4) AND A>=REF(H,3) AND A>=REF(H,1) AND A>=H;{中間K線的最高價(jià)大于等于兩邊共四根K線的最高價(jià)}
D:=BACKSET(B,3);{將當(dāng)前位置和之前2個(gè)周期的數(shù)值設(shè)為1}
HD:FILTER(D,2);{找到高點(diǎn)后，過濾掉其后2周期內(nèi)可能出現(xiàn)的等高點(diǎn)。輸出高點(diǎn)}
A2:=REF(L,2);{中間K線的最低價(jià)}
B2:=A2<=REF(L,4) AND A2<=REF(L,3) AND A2<=REF(L,1) AND A2<=L;{中間K線的最低價(jià)小于等于兩邊共四根K線的最低價(jià)}
D2:=BACKSET(B2,3);{將當(dāng)前位置和之前2個(gè)周期的數(shù)值設(shè)為1}
LD:FILTER(D2,2);{找到低點(diǎn)后，過濾掉其后2周期內(nèi)可能出現(xiàn)的等低點(diǎn)。輸出低點(diǎn)}
{后面有些例子，就從這個(gè)公式中引用信號。}
用法: DRAWICON(COND,PRICE,TYPE),當(dāng)COND條件滿足時(shí),在PRICE位置畫TYPE號圖標(biāo)。15種圖標(biāo)編碼為1-15（1-3為小臉,4-5為上下箭頭,6-7為紅綠小旗,8-9為三角形,10-12為信號燈,13-15為O、X、四方形）。TYPE為字符串時(shí)可顯示用戶自制BMP圖。
示例：DRAWICON(CLOSE>OPEN,LOW,4)表示當(dāng)收陽時(shí)在最低價(jià)位置畫4號圖標(biāo)。
DRAWICON(C>O, L, 'MyBMP')表示當(dāng)收陽時(shí)在最低價(jià)位置畫FmlDLL子目錄下的自制圖標(biāo)MyBMP.BMP。
1、COND條件，一般是指判斷的結(jié)果，不是0就是1。如用其它數(shù)據(jù)，大于等于1的，條件滿足；小于1，條件就不滿足。
2、TYPE圖標(biāo)，現(xiàn)在已經(jīng)有12種，用下面的公式，在000829上可以全部顯示出來。當(dāng)TYPE取大于等于12的數(shù)時(shí)，都顯示黃球。
當(dāng)TYPE取0時(shí)，顯示的是笑臉（這個(gè)公式中沒有做進(jìn)去，自己可以試一下）。
B:="FENG2.HD";
D:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);
A:=D>REF(D,1);
DRAWICON(REF(A,1),1.05*H,1);
DRAWICON(REF(A,2),1.05*H,2);
DRAWICON(REF(A,3),1.05*H,3);
DRAWICON(REF(A,4),1.05*H,4);
DRAWICON(REF(A,5),1.05*H,5);
DRAWICON(REF(A,6),1.05*H,6);
DRAWICON(REF(A,7),1.05*H,7);
DRAWICON(REF(A,8),1.05*H,8);
DRAWICON(REF(A,9),1.05*H,9);
DRAWICON(REF(A,10),1.05*H,10);
DRAWICON(REF(A,11),1.05*H,11);
DRAWICON(REF(A,12),1.05*H,12);
DRAWICON(REF(A,13),1.05*H,13);
DRAWICON(REF(A,14),1.05*H,100);{主圖疊加}
當(dāng)紅球和綠球連續(xù)顯示時(shí)，立體感會(huì)強(qiáng)一些。
DRAWICON(C>=MA(C,30),MA(C,30),10);
DRAWICON(C< MA(C,30),MA(C,30),11);{主圖疊加}
3、PRICE是用于定位圖標(biāo)的位置的。一般用1.01＊H，或者0.99*L等。現(xiàn)在可用ALIGN(0-5)指定對齊位置。
用這個(gè)公式來試（主圖疊加）
B:="FENG2.HD";
D:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);
A:=D>REF(D,1);
E:=REF(H,1);
DRAWICON(A,E,10),ALIGN0;
DRAWICON(A,E,11),ALIGN1;
DRAWICON(A,E,12),ALIGN2;
DRAWICON(A,E,3),ALIGN3;
DRAWICON(A,E,4),ALIGN4;
DRAWICON(A,E,5),ALIGN5;
可以初步得出結(jié)論：
ALIGN0：信號出現(xiàn)在PRICE的正中；
ALIGN1：信號出現(xiàn)在PRICE下邊（十分靠近）；
ALIGN2：信號出現(xiàn)在PRICE上邊（十分靠近）；
ALIGN3：信號出現(xiàn)在主圖的中間；
ALIGN4：信號出現(xiàn)在主圖的最上邊；
ALIGN5：信號出現(xiàn)在主圖的最下邊；
在高低點(diǎn)上作圖標(biāo)，可以使高低點(diǎn)更明確了。
A:="FENG2.LD";
B:="FENG2.HD";
DRAWICON(A,L,11),ALIGN1;
DRAWICON(B,H,10),ALIGN2;{主圖疊加}
4、可以自由調(diào)用MyBMP.BMP圖到顯示位置，大大增強(qiáng)了輸出的效果。你只要看到好看的圖，可以隨時(shí)抓拍過來，做成BMP文件，放到FmlDLL子目錄下，就可以調(diào)用了。
A:="FENG2.LD";
B:="FENG2.HD";
DRAWICON(A,L,'PIG'),ALIGN1;
DRAWICON(B,H,'PIG'),ALIGN2;{主圖疊加。如果你沒有PIG.BMP文件，則不可顯示。}
DRAWICON(1,MA(C,5),'S28');
DRAWICON(1,MA(C,10),'S31');
DRAWICON(1,MA(C,20),'S14');
DRAWICON(1,MA(C,30),'S25');{主圖疊加。如果你沒有PIG.BMP文件，則不可顯示。}
舉個(gè)例子：
A:="FENG2.LD";
B:="FENG2.HD";
DRAWICON(A,L,11),ALIGN1;
DRAWICON(B,H,10),ALIGN2;
D:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);
E:=D>REF(D,1);
F:=BACKSET(E,REF(BARSLAST(B),1)+2);
G:=F>REF(F,1);
DRAWLINE(G,H,E,H,1),pointdot,linethick1,coloryellow;{主圖疊加}
這根線有些趨勢線的意思了。由于趨勢線的主觀性頗強(qiáng)，只有多設(shè)參數(shù)才能滿足多數(shù)人的要求。
DRAWLINE畫出的線，應(yīng)該比手工畫出的線精確一些（DRAWLINE畫線的靈敏度，要比手工畫線低，所以說DRAWLINE畫出的線精確，就未必對）。
主要用于畫斜線，水平線我們一般可以另想辦法。因?yàn)樵趫D中顯示直線，并非DRAWLINE的"專利"。
比如：
A:="FENG2.LD";
B:="FENG2.HD";
D:=BACKSET(ISLASTPERIOD,BARSLAST(A)+1);
E:=D>REF(D,1);
F:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);
G:=F>REF(F,1);
前高:REF(H,BARSLAST(G));
前低:REF(L,BARSLAST(E));{主圖疊加}
說明：在圖形上顯示數(shù)字
用法: DRAWNUMBER(COND,PRICE,NUMBER,PRECISION),當(dāng)COND條件滿足時(shí),在PRICE位置書寫數(shù)字NUMBER（可以為常數(shù)或數(shù)組序列）,PRECISION為小數(shù)顯示位數(shù)(取值范圍0-3)?？葾LIGN0-5定義對齊方式。
示例：DRAWNUMBER(CLOSE/OPEN>1.08,HIGH,(CLOSE-REF(C,1))/REF(C,1)*100,2)表示當(dāng)日漲幅大于8%時(shí)在最高價(jià)位置顯示漲幅(相對開盤價(jià)的百分比)。
這個(gè)函數(shù)的特色是，在NUMBER位置可以放變量。
NUMBER,數(shù)字。DRAWNUMBER是DRAWTEXT的"兄弟"，也可以用ALIGN(0-5)來定義水平位置，方法相同。
A:="FENG2.LD";
B:="FENG2.HD";
DRAWICON(A,L,11),ALIGN1;
DRAWICON(B,H,10),ALIGN2;
D1:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);
E1:=D1>REF(D1,1);{離目前最近的一個(gè)高點(diǎn)}
D2:=BACKSET(E1,REF(BARSLAST(B),1)+2);
E2:=D2>REF(D2,1);{倒數(shù)第二個(gè)高點(diǎn)}
DRAWTEXT(E1,H*1.02,'高點(diǎn)價(jià)：'),COLORGREEN,ALIGN2;
DRAWNUMBER(E1,H*1.02,H,2),COLORGREEN,ALIGN1;
DRAWTEXT(E2,H*1.02,'高點(diǎn)價(jià)：'),COLORYELLOW,ALIGN2;
DRAWNUMBER(E2,H*1.02,H,2),COLORYELLOW,ALIGN1;{主圖疊加}
A:="FENG2.LD";
B:="FENG2.HD";
DRAWICON(A,L,11),ALIGN1;
DRAWICON(B,H,10),ALIGN2;
D1:=BACKSET(ISLASTPERIOD,BARSLAST(B)+1);
E1:=D1>REF(D1,1);{離目前最近的一個(gè)高點(diǎn)}
D2:=BACKSET(E1,REF(BARSLAST(B),1)+2);
E2:=D2>REF(D2,1);{倒數(shù)第二個(gè)高點(diǎn)}
D3:=BACKSET(E2,REF(BARSLAST(B),1)+2);
E3:=D3>REF(D3,1);{倒數(shù)第三個(gè)高點(diǎn)}
DRAWTEXT(E1,H*1.01,'☆TEXT:'),COLORRED,ALIGN0;
DRAWTEXT(E2,H*1.01,'★TEXT:'),COLORGREEN,ALIGN1;
DRAWTEXT(E3,H*1.01,'▓TEXT:'),COLORYELLOW,ALIGN2;{主圖疊加}
描述：繪制折線段
類別：繪圖
說明：在圖形上繪制折線段
用法: POLYLINE(COND,PRICE),當(dāng)COND條件滿足時(shí),以PRICE位置為頂點(diǎn)畫折線連接。
示例：POLYLINE(HIGH>=HHV(HIGH,10),HIGH)表示在創(chuàng)10天新高點(diǎn)之間畫折線。
POLY，多個(gè)的。
支持POINTDOT、LINETHICK、COLOR、SHIFT這四個(gè)描述函數(shù)。
A:="FENG2.LD";
B:="FENG2.HD";
DRAWICON(A,L,11),ALIGN1;
DRAWICON(B,H,10),ALIGN2;
POLYLINE(A,L),POINTDOT,COLORGREEN;
POLYLINE(B,H),LINETHICK2,COLORMAGENTA;{主圖疊加}
參數(shù)可調(diào)整的峰點(diǎn)公式：
A:=REF(H,N)=HHV(H,2*N+1);{當(dāng)前位置N天之前的最高價(jià)是最近2*N+1根K線中的最高價(jià)}
B:=FILTER(A,N); {當(dāng)高點(diǎn)附近有等高的K線出現(xiàn)時(shí)，會(huì)影響后續(xù)高點(diǎn)的判斷，所以要過濾}
D:=BACKSET(B,N+1);{將當(dāng)前位置及前N周期的數(shù)值設(shè)為1，所以要用N+1}
HD:=FILTER(D,N); {當(dāng)高點(diǎn)附近有等高的K線出現(xiàn)，取第一個(gè)，過濾掉后面N個(gè)周期之內(nèi)出現(xiàn)的}
A2:=REF(L,N)=LLV(L,2*N+1);{求低點(diǎn)的過程與求高點(diǎn)的過程同理}
B2:=FILTER(A2,N);
D2:=BACKSET(B2,N+1);{參數(shù)N:1,3,999}
LD:=FILTER(D2,N);{主圖疊加}
DRAWICON(HD,H,10),ALIGN2;{在高點(diǎn)附近顯示紅球}
DRAWICON(LD,L,11),ALIGN1;{在低點(diǎn)附近顯示綠球}
可以說，這個(gè)公式用了未來函數(shù)BACKSET，但是用在日K線中，盤后是沒有未來數(shù)據(jù)的，因?yàn)橐玫娜且呀?jīng)發(fā)生過的不可變的數(shù)據(jù)了。
至于即時(shí)盤中的未來數(shù)據(jù)，那是說不到底的事，基本所有的公式，都有即時(shí)盤中未來數(shù)據(jù)。
紅球綠球作為峰點(diǎn)標(biāo)志，在顯示K線不多的情況下，還比較清楚。但當(dāng)K線數(shù)較多時(shí)，因?yàn)榍虻拇笮∈遣蛔兊?，所以看起來比較亂。故可用以下公式：
A:=REF(H,N)=HHV(H,2*N+1); B:=FILTER(A,N); D:=BACKSET(B,N+1); HD:=FILTER(D,N);
A2:=REF(L,N)=LLV(L,2*N+1);B2:=FILTER(A2,N); D2:=BACKSET(B2,N+1);LD:=FILTER(D2,N);
STICKLINE(REF(HD,1),REF(H,1),REF(H,1),18,0),COLORMAGENTA;
STICKLINE(REF(LD,1),REF(L,1),REF(L,1),18,0),COLORGREEN;
函數(shù)：HHVBARS(X,N)
描述：上一高點(diǎn)位置
類別：引用
參數(shù)：X為數(shù)組，N為計(jì)算周期
返回：返回?cái)?shù)組
說明：求N周期內(nèi)X最高值到當(dāng)前周期數(shù)，N=0表示從第一個(gè)有效值開始統(tǒng)計(jì)
示例：HHVBARS(HIGH,0)求得歷史新高到當(dāng)前的周期數(shù)
HHV、HHVBARS這兩個(gè)函數(shù)一起用，可以找到當(dāng)前N天中的最高點(diǎn)。
A:=BACKSET(ISLASTPERIOD,HHVBARS(H,N)+1);
B:=COUNT(A,N)=1;{取得前N個(gè)周期內(nèi)的最高點(diǎn)位置}
REF(H,BARSLAST(B));
DRAWICON(B,H,1),ALIGN2;{主圖疊加。N：30,1,9999}
函數(shù)：LLVBARS(X,N)
描述：上一低點(diǎn)位置
類別：引用
參數(shù)： 無
返回： 無
說明：求N周期內(nèi)X最低值到當(dāng)前周期數(shù)，N=0表示從第一個(gè)有效值開始統(tǒng)計(jì)
示例：LLVBARS(HIGH,10)求得10日最低點(diǎn)到當(dāng)前的周期數(shù)
當(dāng)前N天之內(nèi)的最高點(diǎn)和最低點(diǎn)就一目了然了：
A:=BACKSET(ISLASTPERIOD,HHVBARS(H,N)+1);
B:=COUNT(A,N)=1;{取得前N個(gè)周期內(nèi)的最高點(diǎn)位置}
REF(H,BARSLAST(B));
DRAWICON(B,H,1),ALIGN2;
A2:=BACKSET(ISLASTPERIOD,LLVBARS(L,N)+1);
B2:=COUNT(A2,N)=1;{取得前N個(gè)周期內(nèi)的最低點(diǎn)位置}
REF(L,BARSLAST(B2));
DRAWICON(B2,L,2),ALIGN1;{主圖疊加。N：30,1,9999}
這個(gè)公式求前期高低點(diǎn)，在600036等次新股上試調(diào)整參數(shù)就露馬腳了，并不完善。問題出在HHVBARS起算點(diǎn)等原因上。
下面這個(gè)公式可以說是完美解決方案：
HH:HHV(H,N),LINETHICK2;
LL:LLV(L,N),LINETHICK2;{主圖疊加，參數(shù)N：30，1,9999}
當(dāng)N個(gè)周期之內(nèi)，有兩個(gè)最高價(jià)，即有等高的情況出現(xiàn)，HHVBARS會(huì)返回哪個(gè)最高價(jià)到當(dāng)前的周期數(shù)呢？
用副圖公式觀察一下，N取10：
HHVBARS(H,N);
我們可以得出結(jié)論，返回的是前一個(gè)最高價(jià)到當(dāng)前的周期數(shù)。同樣，當(dāng)在N個(gè)周期之內(nèi)，有兩個(gè)等低的最低價(jià)出現(xiàn)時(shí)，LLVBARS會(huì)返回前一個(gè)最低價(jià)到當(dāng)前的周期數(shù)。
工具箱
【 · 發(fā)布:于瑤 2004-10-09 23:19 】
0079--窄幅整理
(HHV(C,20)-LLV(C,20)/C<0.08;
工具箱
【 · 發(fā)布:于瑤 2004-10-09 23:19 】
0080--N天前到M天前之間的最高價(jià)
REF(HHV(H,20),40);
工具箱
【 · 發(fā)布:于瑤 2004-10-09 23:20 】
0081--某時(shí)間段最高價(jià)
HH:=IF(YEAR=1998 AND MONTH>=8 AND MONTH<=12,H,0);
HHV(HH,0);{此例求1998年8月1日到1998年12月31日間的最高價(jià)}
工具箱
【 · 發(fā)布:于瑤 2004-10-09 23:21 】
0082--二十日內(nèi)是否有過漲停
TT:=C/REF(C,1)>1.095;
COUNT(TT,20)>0;
工具箱
【 · 發(fā)布:于瑤 2004-10-09 23:22 】
0083--放量創(chuàng)新高
AA:=MA(V,5);
BB:=REF(AA,2);
CC:=HHV(C,30);
AA/BB>2 AND C=CC;
工具箱
【 · 發(fā)布:于瑤 2004-10-09 23:23 】
0084--突破長期平臺(tái)整理
V1:=MA(V,5);
V2:=V/REF(V1,1);
PZ1:=MA(C,150);
PZ2:=HHV(H,150);
PZ3:=LLV(L,150);
PZ4:=(PZ2-PZ1)/PZ1;
PZ5:=(PZ1-PZ3)/PZ1;
PZ:=REF(PZ4,1)<0.15 AND REF(PZ5,1)<0.15;
TP1:=HHV(H,150);
TP:=H=TP1;
V2>=2 AND PZ AND TP
工具箱
【 · 發(fā)布:于瑤 2004-10-09 23:24 】
0085--尾盤大單拉升或打壓
AA:=TIME>=145500;
BB:=SUM(V,0)/240;//當(dāng)天均量
CC:=SUM(V,10)/10;//10分鐘內(nèi)的成交均量
DD:=REF(C,10);
AA AND CC/BB>3 AND C/DD>1.02;
工具箱
【 · 發(fā)布:于瑤 2004-10-10 01:19 】
0086--MACD柱狀體變寬語法
Moving Average Convergence/Divergence , MACD , 移動(dòng)平均收斂/發(fā)散指針
Param(LONG , 26 ,20 100)
Param(SHORT , 12 , 5 ,40)
Param(M , 9 , 2 , 60)
DIFF:EMA( CLOSE , SHORT ) - EMA( CLOSE , LONG) ,LINETHICK0,COLOR99FFFF;
DEA:EMA( DIFF , M ) ,LINETHICK0,COLORFF9966;
MACD: 2 * ( DIFF - DEA ) ,LINETHICK0,COLOR9966FF;
STICKLINE(MACD>0,0,MACD,6,1) ,COLOR9966FF;
STICKLINE(MACD<=0,0,MACD,6,1) ,COLORCCFF66;
PARTLINE(C>0,DIFF) ,COLOR99FFFF;
PARTLINE(C>0,DEA) ,COLORFF9966;
英譯：
DIFF=Difference = 差異=差離值
DEA=Difference Exponential Average= 差異的指數(shù)平滑移動(dòng)平均=差離值平均值
MACD=Moving Average Convergence/Divergence = 移動(dòng)平均收斂/發(fā)散
利用快速和慢速兩條指數(shù)平滑移動(dòng)平均線，計(jì)算兩者之間的差離值DIFF
再利用差離值DIFF，來計(jì)算差離值平均值DEA
本公式MACD柱狀，即可明顯體現(xiàn)出了DIFF與DEA兩者的收斂交會(huì)與發(fā)散分離的情況，
用以研判買進(jìn)或賣出的時(shí)機(jī)
工具箱
【 · 發(fā)布:于瑤 2004-10-10 01:20 】
0087--傅立葉變換
用法：FFT(X , N)
傅立葉變換，對數(shù)列X進(jìn)行傅立葉變換，或變換處理后反變換
示例：
當(dāng)N=0時(shí)，對數(shù)列X進(jìn)行傅立葉變換；
當(dāng)N=1時(shí)，對數(shù)列X進(jìn)行傅立葉變換后，再反變換回來，與原X一致；
當(dāng)N>1時(shí)，對數(shù)列X進(jìn)行傅立葉變換后，舍去周期小于N的成分后再反變換回來；
傅立葉變換是最常用的積分變換。原理和對數(shù)變換等差不多，廣泛應(yīng)用于工程技術(shù)領(lǐng)域?？筛盗⑷~變換的算法，涉及高等數(shù)學(xué)的微積分知識，非三言兩語說得清楚。
傅立葉變換的應(yīng)用方面：把FFT(CLOSE,30)，在主圖中上移、下移之后，可以構(gòu)成非常光滑的信道。
AA:FFT(CLOSE,30);
XX:AA*1.05;
YY:AA*0.95;
工具箱
【 · 發(fā)布:于瑤 2004-10-10 01:21 】
0088--周期切換
函數(shù)： DATATYPE
別名： DATAPERIOD,、數(shù)據(jù)周期類型
用法：
DATATYPE
回傳值竹范圍為0-11
分別表示分筆成交、1分鐘、5分鐘、15分鐘、30分鐘、60分鐘、
日、周、月、年、多日、多分鐘
范例：切換到日線時(shí)跑最高價(jià)、切換到周線時(shí)跑最低價(jià)?？紤]到什么周期秀什么線的問題
XH:=IF( DATATYPE=6 , 1 , 0 ) ;
XL:=IF( DATATYPE=7 , 1 , 0 ) ;
AA:=MA(C , XH)/MA(C , XH) ;
BB:=MA(C , XL)/MA(C , XL) ;
HH:=HIGH ;
LL:=LOW ;
日線最高價(jià):AA*HH , COLORGREEN ;
周線最低價(jià):BB*LL , COLORYELLOW ;
范例：切換到指數(shù)類STKTYPE=0 跑10均線，切換到個(gè)股類STKTYPE=5 跑30均線。
XA:=IF( STKTYPE=0 , 1 , 0 ) ;
XB:=IF( STKTYPE=5 , 1 , 0 ) ;
AA:=IF( XA=1 , MA(C,10) , 0 ) ;
BB:=IF( XB=1 , MA(C,30) , 0 ) ;
指針線:AA+BB ;
范例：標(biāo)記當(dāng)天分時(shí)K線的當(dāng)天K線序號。過了午夜12點(diǎn)，就又要等早盤開盤后序號數(shù)字才會(huì)出現(xiàn)
XA:=CURRENTDATE=DATE ;
XB:=REF(XA , 1)<>XA ;
XC:HHVBARS(XB , 0) + XA ;
應(yīng)用：13均線當(dāng)天當(dāng)下最后數(shù)值向后延申，畫平臺(tái)線。
XA:=CURRENTDATE=DATE ;
XB:=REF(XA , 1)<>XA ;
XC:=HHVBARS(XB , 0) + XA ;
XD:=MA(C,13);
XE:=REFX(XD , 300);
XF:IF(XC>=0 , XE , 0) ,LINETHICK0,COLOR99FFFF;
PARTLINE(XC>=1 , XF) ,COLOR99FFFF;
工具箱
【 · 發(fā)布:于瑤 2004-10-10 01:21 】
0089--公歷農(nóng)歷
范例：公歷日期
YY:=YEAR*10000;
MM:=MONTH*100;
DD:=DAY ;
公歷日期:YY+MM+DD ,LINETHICK0;
范例：農(nóng)歷日期
LY:=LYEAR*10000;
LM:=LMONTH*100;
LD:=LDAY;
農(nóng)歷日期:LY+LM+LD ,LINETHICK0;
范例：兩個(gè)日期相差天數(shù)→橫坐標(biāo)切換→自然日坐標(biāo)和交易日坐標(biāo)效果不一樣
兩日期相差天數(shù)A: DATEDIFF(1020929,1021003),LINETHICK0;
兩日期相差天數(shù)B: DATEDIFF(LSOLARTERMDATE(1), DATE),LINETHICK0;
范例：9點(diǎn):30分:59秒以前的分時(shí)K線，指定一個(gè)值=1給它，其它為=0
N:=30;
XA:IF((HOUR=8) OR (HOUR=9 AND MINUTE>=0 AND MINUTE<=N) , 1 , 0 ) , STICK ;
上面和下面的語法，其意義相同：
范例：9點(diǎn):30分:59秒 以前的分時(shí)K線 ，指定一個(gè)值=1給它，其它為=0
N:=30;
XA:(HOUR=8) OR (HOUR=9 AND MINUTE>=0 AND MINUTE<=N) , STICK ;
范例：開盤第一根分時(shí)K線，指定一個(gè)值=1給它，其它為0
XA:REF(DATE,1)<>DATE , STICK;
范例：每天的分時(shí)K線，指定它的當(dāng)天K線序號給它
XA:=REF(DATE,1)<>DATE , STICK;
XB:BARSLAST(XA=1) + 1 ,STICK;
|
|
